jgoodies-looks-2.6.0.ebuild

jgoodies-looks-2.6.0.ebuild (text/plain), 1.30 KB, created by Small_Penguin on 2014-03-14 19:48:08 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2 eutils

MY_PN="looks"
MY_PV=${PV//./_}
MY_P="${PN}-${MY_PV}"
DESCRIPTION="JGoodies Looks Library"
HOMEPAGE="http://www.jgoodies.com/"
SRC_URI="http://www.jgoodies.com/download/libraries/${MY_PN}/${MY_P}.zip"

LICENSE="BSD"
SLOT="2.0"
KEYWORDS="~amd64"
IUSE=""

COMMON_DEPEND=">=dev-java/jgoodies-common-1.8.0:0"
DEPEND=">=virtual/jdk-1.6
	app-arch/unzip
	app-arch/zip
	${COMMON_DEPEND}"
RDEPEND=">=virtual/jre-1.6
	${COMMON_DEPEND}"

src_unpack() {
	default
	cd "${S}"
	mkdir src && cd src &&  unzip -qq ../${P}-sources.jar || die
	find "${S}" -name '*.jar' -exec rm -v {} +
}

src_compile() {
	mkdir "${S}/classes"

	find src -name "*.java" > "${T}/src.list"
	ejavac -encoding ISO-8859-1 -classpath "$(java-pkg_getjars jgoodies-common)" \
	  -d "${S}/classes" "@${T}/src.list"

	cd "${S}/classes"
	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
	find "{S}/src" -name "*.java" -delete
	cd "${S}/src"
	zip -r "${S}/${PN}.jar" .|| die "can't update jar with resources"
}

src_install() {
	java-pkg_dojar ${PN}.jar

	dodoc RELEASE-NOTES.txt README.html || die

	use doc && java-pkg_dohtml -r docs/*
	use source && java-pkg_dosrc src/com
}