# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 eutils

IUSE="ssl gtkhtml perl ldap crypt kerberos"
DESCRIPTION="Email client for GNOME"
SRC_URI="http://balsa.gnome.org/${P}.tar.bz2"
HOMEPAGE="http://balsa.gnome.org"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~ppc ~sparc alpha"

RDEPEND="net-mail/mailbase
	>=gnome-base/libgnomeui-2
	>=gnome-base/libgnomeprintui-2.1.4
	>=net-libs/libesmtp-1.0-r1
	>=dev-libs/gmime-2.1.7
	sys-devel/libtool
	virtual/aspell-dict
	ssl? ( dev-libs/openssl )
	perl? ( >=dev-libs/libpcre-3.4 )
	gtkhtml? ( =gnome-extra/libgtkhtml-2* )
	ldap? ( net-nds/openldap )
	kerberos? ( app-crypt/mit-krb5 )
	crypt? ( >=app-crypt/gpgme-0.9.0 )"

DEPEND="dev-util/pkgconfig
	>=app-text/scrollkeeper-0.1.4
	${RDEPEND}"

src_compile() {
	local myconf

	use gtkhtml || myconf="${myconf} --disable-gtkhtml"
	use crypt && myconf="${myconf} --with-gpgme=gpgme-config"
		
	econf \
		`use_with ssl` \
		`use_enable perl pcre` \
		`use_with ldap` \
		`use_with kerberos gss` \
		${myconf} || die "configure failed"

	emake || die "emake failed"
}

DOCS="AUTHORS COPYING ChangeLog HACKING INSTALL NEWS README TODO docs/*"