# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils git-2 linux-info toolchain-funcs user

EGIT_REPO_URI="git://github.com/tvheadend/tvheadend.git"

DESCRIPTION="Tvheadend is a TV streaming server for Linux"
HOMEPAGE="https://tvheadend.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""

IUSE="avahi ccache curl dvb dvbscan ffmpeg imagecache inotify uriparser xmltv zlib"

REQUIRED_USE="
	dvbscan? ( dvb )
	imagecache? ( curl )"

DEPEND="dev-libs/openssl
	uriparser? ( dev-libs/uriparser )
	ccache? ( dev-util/ccache )
	avahi? ( net-dns/avahi )
	curl? ( net-misc/curl )
	zlib? ( sys-libs/zlib )
	ffmpeg? ( virtual/ffmpeg )
	dvb? ( virtual/linuxtv-dvb-headers )
	virtual/pkgconfig"

RDEPEND="${DEPEND}
	dvbscan? ( media-tv/linuxtv-dvb-apps )
	xmltv? ( media-tv/xmltv )"

CONFIG_CHECK="~INOTIFY_USER"

DOCS=( README )

pkg_setup() {
	enewuser tvheadend -1 -1 /dev/null video
}

src_prepare() {
	# remove '-Werror' wrt bug #438424
	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
}

src_configure() {
	econf --prefix="${EPREFIX}"/usr \
		--datadir="${EPREFIX}"/usr/share \
		$(use_enable avahi) \
		$(use_enable ccache) \
		$(use_enable curl) \
		--disable-dvbscan \
		$(use_enable ffmpeg libav) \
		$(use_enable imagecache) \
		$(use_enable inotify) \
		$(use_enable dvb linuxdvb) \
		$(use_enable uriparser) \
		$(use_enable zlib)
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	default

	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
	newconfd "${FILESDIR}/tvheadend.confd" tvheadend

	dodir /etc/tvheadend
	fperms 0700 /etc/tvheadend
	fowners tvheadend:video /etc/tvheadend
}

pkg_postinst() {
	elog "The Tvheadend web interface can be reached at:"
	elog "http://localhost:9981/"
	elog
	elog "Make sure that you change the default username"
	elog "and password via the Configuration / Access control"
	elog "tab in the web interface."
}