binwalk-1.3.0.ebuild

binwalk-1.3.0.ebuild (text/plain), 1000 bytes, created by Azamat H. Hackimov on 2014-02-20 19:10:47 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/binwalk/binwalk-1.2.2_p1.ebuild,v 1.1 2013/11/06 06:56:15 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_2,3_3} )

inherit distutils-r1

DESCRIPTION="A tool for identifying files embedded inside firmware images"
HOMEPAGE="http://binwalk.org/"
SRC_URI="https://github.com/devttys0/binwalk/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~mips ~x86"
IUSE="graph"

RDEPEND="app-crypt/ssdeep
	sys-apps/file[python]
	graph? ( dev-python/pyqtgraph[${PYTHON_USEDEP}] )"

S=${WORKDIR}/${P}/src

DOCS=( ../README.md ../API )

PATCHES=(
	"${FILESDIR}"/${P}-no-install-libs.patch
	"${FILESDIR}"/${P}-parallel-make.patch
)

python_configure_all() {
	mydistutilsargs=( --yes )
	cd C
	econf
}

python_compile_all() {
	cd C
	emake
}

python_install_all() {
	distutils-r1_python_install_all
	cd C
	emake DESTDIR="${D}" install
}