# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/media-sound/glame/glame-0.6.3.ebuild,v 1.1 2002/08/06 04:26:04 leonardop Exp $

S=${WORKDIR}/${P}
DESCRIPTION="Glame is an audio file editing utility"
SRC_URI="mirror://sourceforge/glame/${P}.tar.gz"
HOMEPAGE="http://glame.sourceforge.net/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="x86"

DEPEND=">=dev-libs/glib-1.2.10-r4
		>=dev-libs/libxml-1.8.17-r2
		>=dev-util/guile-1.4-r3
		>=media-libs/audiofile-0.2.3-r1
		>=media-libs/imlib-1.9.14-r1
		>=media-sound/esound-0.2.28-r1
		>=sys-libs/db-1.85-r1
		>=sys-libs/ncurses-5.2-r6
		>=sys-libs/zlib-1.1.4
		virtual/glibc
		X? ( >=gnome-base/gnome-libs-1.4.2
			<gnome-base/libglade-2
			<x11-libs/gtk+-2
			virtual/x11 )"

RDEPEND="nls? ( sys-devel/gettext )"

src_compile() {
	if [ "`use X`" ]
	then
		cd src/gui

		# Use a valid icon for the GNOME menu entry
		cp glame.desktop glame.desktop.old
		sed -e 's:glame.png:glame-logo.jpg:' \
			glame.desktop.old > glame.desktop

		# XXX check this if something breaks on version bump
		# This include seems gratuitous, and breaks the build
		# if not USE'ing nls. (removing it doesnt hurt if you 
		# are, though)
		cp swapfilegui.c swapfilegui.c.orig
		sed -e '/^#include <libintl.h>/d' \
			swapfilegui.c.orig > swapfilegui.c

		cd ../..
	fi
	
	local myconf="--with-included-gettext"

	use nls || myconf="$myconf --disable-nls"
	use X   || myconf="$myconf --disable-gui"
	
	econf $myconf || die "Configuration failed"
	
	emake || die "Compilation failed"
}

src_install () {
	einstall || die "Installation failed"
	
	if [ "`use X`" ]
	then
		dodir /usr/share/pixmaps
		dosym ../glame/pixmaps/glame-logo.jpg \
		      /usr/share/pixmaps/glame-logo.jpg
	fi
	
	dodoc ABOUT-NLS AUTHORS BUGS COPYING CREDITS ChangeLog MAINTAINERS \
		NEWS README TODO
}