# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils java-pkg-2

SRC_PN="yEd"
SRC_P="${SRC_PN}-${PV}"
MY_PN="yed"
S="${WORKDIR}/${MY_PN}-${PV}"

DESCRIPTION="Effective high-quality diagrams editor"
HOMEPAGE="http://www.yworks.com/en/products_yed_about.html"
SRC_URI="${SRC_P}.zip"
DOWNLOAD_URL="http://www.yworks.com/en/products_download.php?file=${SRC_URI}"

LICENSE="yEd-1.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

JAVA_GENTOO_CLASSPATH="freehep-graphics2d;
freehep-graphicsio;
freehep-graphicsio-emf;
freehep-graphicsio-pdf;
freehep-graphicsio-ps;
freehep-graphicsio-swf;
freehep-util"

RDEPEND=">=virtual/jre-1.7
dev-java/freehep-graphics2d
dev-java/freehep-graphicsio
dev-java/freehep-graphicsio-emf
dev-java/freehep-graphicsio-pdf
dev-java/freehep-graphicsio-ps
dev-java/freehep-graphicsio-swf
dev-java/freehep-util"
DEPEND="app-arch/unzip ${RDEPEND}"

RESTRICT="fetch"

pkg_nofetch() {
	eerror "${SRC_URI} not found!"
	echo
	elog "Please download the ${SRC_URI} from"
	elog "  ${DOWNLOAD_URL}"
	elog "and place it in ${DISTDIR}."
}

src_install() {
	local dest=/opt/${PN}

	java-pkg_jarinto ${dest}
	java-pkg_dojar ${MY_PN}.jar
	java-pkg_dojar vectorgraphics.jar
	java-pkg_dolauncher "${PN}" --jar ${MY_PN}.jar

	doicon icons/yicon32.png || die
	make_desktop_entry "${PN}" "yEd Graph Editor" Graphics
}