nagios-check_rbl-1.3.2.ebuild

nagios-check_rbl-1.3.2.ebuild (text/plain), 1.23 KB, created by Michael Orlitzky on 2014-02-01 18:28:25 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit multilib

DESCRIPTION="check_rbl is a Nagios plugin that fails if a host is blacklisted"
HOMEPAGE="https://svn.id.ethz.ch/projects/nagios_plugins/wiki/check_rbl"

MY_P="${P/nagios-/}"

SRC_URI="https://svn.id.ethz.ch/projects/nagios_plugins/downloads/${MY_P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"

KEYWORDS="~amd64 ~hppa ~x86"
IUSE=""

# The package's INSTALL/Makefile.PL files specify its dependencies.
#
#   * IO::Select (dev-lang/perl)
#   * Nagios::Plugin (dev-perl/Nagios-Plugin)
#   * Nagios::Plugin::Getopt (dev-perl/Nagios-Plugin)
#   * Nagios::Plugin::Threshold (dev-perl/Nagios-Plugin)
#   * Net::DNS (dev-perl/Net-DNS)
#   * Readonly (dev-perl/Readonly)
#
RDEPEND="dev-lang/perl
	dev-perl/Nagios-Plugin
	dev-perl/Net-DNS
	dev-perl/Readonly"
DEPEND="${RDEPEND}
	virtual/perl-ExtUtils-MakeMaker"

S="${WORKDIR}/${MY_P}"

src_configure() {
	perl Makefile.PL INSTALLDIRS=vendor || die
}

src_install() {
	default

	local nagiosplugindir=/usr/$(get_libdir)/nagios/plugins
	# move this aftertime as it's a bit strange otherwise
	dodir "${nagiosplugindir}"
	mv "${D}"/usr/bin/check_rbl "${D}"/"${nagiosplugindir}" || die
}