# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

WX_GTK_VER="2.8"

inherit eutils subversion wxwidgets games

MY_PV="r${PV%_*}-alpha"
MY_P=${PN}-${MY_PV}

DESCRIPTION="A free, real-time strategy game of ancient warfare"
HOMEPAGE="http://play0ad.com/"
ESVN_REPO_URI="http://svn.wildfiregames.com/public/ps/trunk"

LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 as-is"
SLOT="svn"
KEYWORDS=""
IUSE="+audio editor fam +lobby pch test upnp"

RDEPEND="media-gfx/nvidia-texture-tools
	dev-lang/spidermonkey:0
	dev-libs/boost
	dev-libs/libxml2
	media-libs/libpng:0
	media-libs/libsdl[X,opengl,video]
	net-libs/enet:1.3
	lobby? ( net-libs/gloox )
	upnp? ( net-libs/miniupnpc )
	net-misc/curl
	sys-libs/zlib
	virtual/jpeg
	virtual/opengl
	x11-libs/libX11
	x11-libs/libXcursor
	audio? ( media-libs/libogg
	media-libs/libvorbis
	media-libs/openal )
	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( dev-lang/perl )"

S=${WORKDIR}/trunk

CHECKREQS_DISK_USR="1900M"

src_unpack() {
	subversion_src_unpack
}

src_configure() {
	cd build/workspaces || die

	./update-workspaces.sh \
		--with-system-nvtt \
		--with-system-enet \
		--with-system-mozjs185 \
		$(usex pch "" "--without-pch") \
		$(usex test "" "--without-tests") \
		$(usex audio "" "--without-audio") \
		$(usex lobby "" "--without-lobby") \
		$(usex upnp "" "--without-miniupnpc") \
		$(use_enable editor atlas) \
		--bindir="${GAMES_BINDIR}" \
		--libdir="$(games_get_libdir)"/${PN}-${SLOT} \
		--datadir="${GAMES_DATADIR}"/${PN}-${SLOT}
}

src_compile() {
	emake -C build/workspaces/gcc verbose=1
}

src_test() {
	cd binaries/system || die
	./test -libdir "${S}/binaries/system" || die "test phase failed"
}

src_install() {
	# data
	insinto "${GAMES_DATADIR}"/${PN}-${SLOT}
	doins -r binaries/data/*

	# bin
	newgamesbin binaries/system/pyrogenesis 0ad-${SLOT}

	# libs
	exeinto "$(games_get_libdir)"/${PN}-${SLOT}
	doexe binaries/system/libCollada.so
	use editor && doexe binaries/system/libAtlasUI.so

	# other
	dodoc binaries/system/readme.txt
	newicon build/resources/${PN}.png ${PN}-${SLOT}.png
	make_desktop_entry ${PN}-${SLOT} "0 A.D. (svn)"

	# permissions
	prepgamesdirs
}