libvdpau-va-gl-0.2.1.ebuild

libvdpau-va-gl-0.2.1.ebuild (text/plain), 1.12 KB, created by Nikoli on 2014-01-17 13:22:41 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit cmake-utils virtualx pax-utils

DESCRIPTION="VDPAU driver with VA-API/OpenGL backend."
HOMEPAGE="https://github.com/i-rinat/libvdpau-va-gl/"
SRC_URI="https://github.com/i-rinat/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="
	dev-libs/glib:2
	x11-libs/libva[X]
	x11-libs/libvdpau
	x11-libs/libX11
	x11-libs/libXext
	media-libs/glu
	virtual/opengl
	virtual/ffmpeg
"
DEPEND="${RDEPEND}"

DOCS=(ChangeLog README.md)

# fixed in git master: https://github.com/i-rinat/libvdpau-va-gl/issues/6
RESTRICT="test"

src_compile() {
	cmake-utils_src_compile
	if use test; then
		cmake-utils_src_make build-tests
		pax-mark m "${BUILD_DIR}"/tests/test-*
	fi
}

src_test() {
	VIRTUALX_COMMAND=cmake-utils_src_test virtualmake
}

# fixed in new xf86-video-intel: https://bugs.freedesktop.org/show_bug.cgi?id=73507
pkg_postinst() {
	einfo "In order to use vdpau hardware video acceleration via ${PN}"
	einfo "you have to add VDPAU_DRIVER=va_gl to your environment"
}