librime-1.1.ebuild

librime-1.1.ebuild (text/plain), 1.12 KB, created by Yixun Lan on 2014-01-01 14:12:20 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/librime/librime-0.9.9.ebuild,v 1.4 2013/09/02 08:06:22 ago Exp $

EAPI=5

inherit cmake-utils multilib versionator toolchain-funcs

DESCRIPTION="Rime Input Method Engine library"
HOMEPAGE="http://code.google.com/p/rimeime/"
SRC_URI="http://rimeime.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="static-libs test"

RDEPEND="app-i18n/opencc
	dev-cpp/glog
	>=dev-cpp/yaml-cpp-0.5.0
	dev-db/kyotocabinet
	>=dev-libs/boost-1.46.0[threads(+)]
	sys-libs/zlib
	x11-proto/xproto"
DEPEND="${RDEPEND}
	>=sys-devel/gcc-4.8.0
	test? ( dev-cpp/gtest )"

S="${WORKDIR}/${PN}"

pkg_setup() {
	version_is_at_least 4.8.0 "$(gcc-fullversion)" \
		|| die "Sorry, but gcc-4.8.0 and earlier wont work for librime (see bug 496080)."
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_build static-libs STATIC)
		-DBUILD_DATA=OFF
		-DBUILD_SEPARATE_LIBS=OFF
		$(cmake-utils_use_build test TEST)
		-DLIB_INSTALL_DIR=/usr/$(get_libdir)
	)
	cmake-utils_src_configure
}