# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header $

EAPI=4

inherit pam eutils multilib toolchain-funcs

DESCRIPTION="Password strength checking for PAM aware password changing programs"
HOMEPAGE="http://www.openwall.com/passwdqc/"
SRC_URI="http://www.openwall.com/passwdqc/${P/pam_/}.tar.gz"

LICENSE="Openwall BSD public-domain"
SLOT="0"
KEYWORDS="~amd64"

DEPEND="virtual/pam"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${P/pam_/}"

src_compile() {
	make_tgt='utils pam'
	emake \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		LDFLAGS_shared_LINUX="--shared ${LDFLAGS}" \
		CC="$(tc-getCC)" \
		LD="$(tc-getCC)" \
		${make_tgt} || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" \
		SHARED_LIBDIR="/$(get_libdir)" \
		install_lib install_utils \
		|| die "emake install_lib install_utils failed"

	doman pam_passwdqc.8
	dopammod pam_passwdqc.so

	dodoc README PLATFORMS INTERNALS pwqcheck.php
}

pkg_postinst() {
	elog
	elog "To activate pam_passwdqc use pam_passwdqc.so instead"
	elog "of pam_cracklib.so in /etc/pam.d/system-auth."
	elog "Also, if you want to change the parameters, read up"
	elog "on the pam_passwdqc(8) and passwdqc.conf(5) man page"
	elog "and the README file in /usr/share/doc/${PF} ."
	elog
}