# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
WANT_ANT_TASKS="ant-nodeps"
JAVA_PKG_IUSE="doc source"

inherit subversion java-pkg-2 java-ant-2

DESCRIPTION="Java3D Core API and Utils package"
HOMEPAGE="https://java3d.java.net/"

ESVN_REPO_URI="http://svn.java.net/svn/${PN}~svn/tags/rel-${PV//./_}-fcs"
ESVN_PROJECT=${P}
ESVN_REPO_URI_2="http://svn.java.net/svn/${PN}-utils~svn/tags/rel-${PV//./_}-fcs"
ESVN_PROJECT_2=${PN}-utils-${PV}

LICENSE="GPL-2-with-exceptions BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

COMMON_DEP="=dev-java/vecmath-${PV}"

RDEPEND=">=virtual/jre-1.5
		${COMMON_DEP}"
DEPEND=">=virtual/jdk-1.5
		app-arch/unzip
		dev-java/eclipse-ecj:3.5[ant]
		${COMMON_DEP}"

src_unpack() {
	subversion_src_unpack

	ESVN_REPO_URI=${ESVN_REPO_URI_2}
	ESVN_PROJECT=${ESVN_PROJECT_2}
	subversion_fetch ${ESVN_REPO_URI_2} ../${PN}-utils
}

src_prepare() {
	cd "${WORKDIR}"
	mkdir -p vecmath/build/opt/lib/ext vecmath/build/debug/lib/ext
	cd vecmath/build/opt/lib/ext
	java-pkg_jarfrom vecmath
	cd "${WORKDIR}/vecmath/build/debug/lib/ext"
	java-pkg_jarfrom vecmath
}

EANT_BUILD_TARGET="jar-opt"
EANT_DOC_TARGET="docs"
ANT_OPTS="-Xmx1g"
JAVA_PKG_FORCE_COMPILER="ecj-3.5"

src_install() {

	local arch=""
	use x86 && arch="linux-i586"
	use amd64 && arch="linux-amd64"
	java-pkg_dojar build/default/opt/lib/ext/*.jar
	java-pkg_doso build/default/opt/native/*.so
	use doc && dohtml "build/${arch}/javadocs"
	use source && java-pkg_dosrc src/classes/jogl/javax src/classes/share/javax \
		src/classes/x11/javax src/classes/win32/javax
}