Updated -9999 ebuild

pkgcore-9999.ebuild (text/plain), 1.49 KB, created by Michał Górny on 2013-08-30 20:40:27 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/pkgcore-9999.ebuild,v 1.11 2013/01/01 14:05:38 mgorny Exp $

EAPI=4

EGIT_REPO_URI="https://code.google.com/p/pkgcore/"
PYTHON_COMPAT=( python{2_6,2_7,3_2} )

inherit distutils-r1 git-2

DESCRIPTION="pkgcore package manager"
HOMEPAGE="http://pkgcore.googlecode.com/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="+doc"

RDEPEND="=dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	dev-python/sphinx[${PYTHON_USEDEP}]
	virtual/pyparsing[${PYTHON_USEDEP}]"

pkg_setup() {
	# disable snakeoil 2to3 caching...
	unset PY2TO3_CACHEDIR

	mydistutilsargs=(
		build
		--disable-html-docs
		--disable-man-pages
	)
}

python_compile_all() {
	esetup.py build_man $(use doc && echo 'build_docs')

	# the build system is too dumb to find the stuff where it put
	# them.
	ln -s "${BUILD_DIR}/sphinx/man" man || die
	# (it's fine to create a dead symlink)
	ln -s "${BUILD_DIR}/sphinx/html" html || die
}

python_test() {
	esetup.py test
}

src_install() {
	# argv, the options are repeated in install ;/
	mydistutilsargs+=(
		install
		--disable-html-docs
		--disable-man-pages
	)

	distutils-r1_src_install
}

python_install_all() {
	local cmds=(
		install_man
	)
	use doc && cmds+=(
		install_docs --path="${ED%/}"/usr/share/doc/${PF}/html
	)

	distutils-r1_python_install "${cmds[@]}"
	distutils-r1_python_install_all
}

pkg_postinst() {
	pplugincache
}