ebuild (net-libs/libesmtp-1.0.3.ebuild)

libesmtp-1.0.3.ebuild (text/plain), 1.34 KB, created by Torsten Stets on 2004-07-15 10:00:43 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libesmtp/libesmtp-1.0.1.ebuild,v 1.3 2004/06/24 23:12:11 agriffis Exp $

inherit gcc eutils gnuconfig libtool

DESCRIPTION="libESMTP is a library that implements the client side of the SMTP protocol"
MY_P=${P}r1
SRC_URI="http://www.stafford.uklinux.net/libesmtp/${MY_P}.tar.bz2"
S=${WORKDIR}/${MY_P}
HOMEPAGE="http://www.stafford.uklinux.net/libesmtp/"
LICENSE="LGPL-2.1 GPL-2"

RDEPEND="ssl? ( >=dev-libs/openssl-0.9.6b )"

DEPEND="${RDEPEND}
	>=sys-devel/libtool-1.4.1
	>=sys-apps/sed-4"

IUSE="ssl debug"
SLOT="0"
KEYWORDS="~x86"

src_compile() {
	gnuconfig_update

	elibtoolize

	local myconf

	use ssl || myconf="${myconf} --without-openssl"

	use debug && myconf="${myconf} --enable-debug"

	if [ "`gcc-major-version`" -eq "2"  ]; then
		myconf="${myconf} --disable-isoc"
	fi

	./configure \
		--prefix=/usr \
		--enable-all \
		--enable-threads \
		${myconf} || die "configure failed"

	if [ "`gcc-major-version`" -eq "3" ] && [ "`gcc-minor-version`" -ge "3" ]; then
		sed -i "s:-Wsign-promo::g" Makefile
	fi

	emake || die "emake failed"
}

src_install () {

	make prefix=${D}/usr install || die "make install failed"
	dodoc AUTHORS COPYING COPYING.GPL INSTALL ChangeLog NEWS Notes README TODO
	dohtml doc/api.xml

}