mylar-99999.ebulid

mylar-99999.ebuild (text/plain), 2.59 KB, created by daktak on 2013-07-09 07:28:46 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

PYTHON_DEPEND="2:2.6"

EGIT_REPO_URI="https://github.com/evilhero/mylar.git"

inherit eutils user git-2 python

DESCRIPTION="Automatic comic book downloader for SABnzbd"
HOMEPAGE="https://github.com/evilhero/mylar#readme"

LICENSE="GPL-2" # only
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

pkg_setup() {
        # Control PYTHON_USE_WITH
        python_set_active_version 2
        python_pkg_setup

        # Create mylar group
        enewgroup ${PN}
        # Create mylar user, put in mylar group
        enewuser ${PN} -1 -1 -1 ${PN}
}

src_install() {
        dodoc README.md 

        newconfd "${FILESDIR}/${PN}.conf" ${PN}
        newinitd "${FILESDIR}/${PN}.init" ${PN}

        # Location of log and data files
        keepdir /var/${PN}
        fowners -R ${PN}:${PN} /var/${PN}

        keepdir /var/{${PN}/{cache,download},log/${PN}}
        fowners -R ${PN}:${PN} /var/{${PN}/{cache,download},log/${PN}}

        insinto /etc/${PN}
        insopts -m0660 -o ${PN} -g ${PN}
        doins "${FILESDIR}/${PN}.ini"

        # Rotation of log files
        insinto /etc/logrotate.d
        insopts -m0644 -o root -g root
        newins "${FILESDIR}/${PN}.logrotate" ${PN}

        # wierd stuff ;-)
        last_commit=$(git rev-parse HEAD)
        echo ${last_commit} > version.txt

        insinto /usr/share/${PN}
        doins -r bs4 cherrypy data mylar lib mako Mylar.py version.txt
}

pkg_postinst() {

        # we need to remove .git which old ebuild installed
        if [[ -d "/usr/share/${PN}/.git" ]] ; then
           ewarn "stale files from previous ebuild detected"
           ewarn "/usr/share/${PN}/.git removed."
           ewarn "To ensure proper operation, you should unmerge package and remove directory /usr/share/${PN} and then emerge package again"
           ewarn "Sorry for the inconvenience"
           rm -Rf "/usr/share/${PN}/.git"
        fi

        python_mod_optimize /usr/share/${PN}

        elog "Headphones has been installed with data directories in /var/${PN}"
        elog
        elog "New user/group ${PN}/${PN} has been created"
        elog
        elog "Config file is located in /etc/${PN}/${PN}.ini"
        elog
        elog "Please configure /etc/conf.d/${PN} before starting as daemon!"
        elog
        elog "Start with ${ROOT}etc/init.d/${PN} start"
        elog "Visit http://<host ip>:8181 to configure Headphones"
        elog "Default web username/password : mylar/secret"
        elog
}

pkg_postrm() {
        python_mod_cleanup /usr/share/${PN}
}