finalterm-9999.ebuild

finalterm-9999.ebuild (text/plain), 1.05 KB, created by Ferenc Erki on 2013-06-25 15:38:17 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
VALA_MIN_API_VERSION="0.16"

inherit cmake-utils git-2 gnome2-utils vala

EGIT_REPO_URI="https://github.com/p-e-w/finalterm.git"

DESCRIPTION="A modern terminal emulator"
HOMEPAGE="http://finalterm.org/"
SRC_URI=""

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="$(vala_depend)
	>=dev-libs/libgee-0.8
	x11-libs/gtk+:3
	>=media-libs/clutter-1.12.2
	media-libs/clutter-gtk
	x11-libs/mx
	dev-libs/keybinder:3"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	vala_src_prepare
	sed -i '/set(CMAKE_C_FLAGS "-ggdb")/d' CMakeLists.txt || die "Sed failed!"
	sed -i "/NAMES/s:valac:${VALAC}:" cmake/FindVala.cmake || die "Sed failed!"
}

src_configure() {
	local mycmakeargs=(-DGSETTINGS_COMPILE=OFF)
	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	gnome2_schemas_update
}