[patch] The patch for the new photofilmstrip-1.9.91-r1.ebuild

photofilmstrip-1.9.91-r1.ebuild.patch (text/plain), 1.79 KB, created by PhobosK on 2013-06-11 16:43:33 UTC

--- /usr/portage/media-video/photofilmstrip/photofilmstrip-1.9.91.ebuild	2013-01-26 20:00:25.000000000 +0200
+++ /usr/local/portage/media-video/photofilmstrip/photofilmstrip-1.9.91-r1.ebuild	2013-06-11 12:18:39.050112705 +0300
@@ -1,13 +1,12 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/photofilmstrip/photofilmstrip-1.9.91.ebuild,v 1.1 2013/01/26 18:00:25 hwoarang Exp $
+# $Header: $
 
 EAPI="5"
-PYTHON_DEPEND="2"
-RESTRICT_PYTHON_ABIS="3.*"
-PYTHON_USE_WITH="sqlite"
+PYTHON_COMPAT=( python2_{6,7} )
+PYTHON_REQ_USE="sqlite"
 
-inherit python distutils
+inherit distutils-r1
 
 DESCRIPTION="Movie slideshow creator using Ken Burns effect"
 HOMEPAGE="http://www.photofilmstrip.org"
@@ -18,19 +17,19 @@
 KEYWORDS="~amd64 ~x86"
 IUSE="cairo sdl"
 
-RDEPEND="dev-python/wxpython:2.8[cairo?]
-	dev-python/imaging
+RDEPEND="dev-python/wxpython:2.8[cairo?,${PYTHON_USEDEP}]
+	virtual/python-imaging[${PYTHON_USEDEP}]
 	media-video/mplayer[encode]
-	sdl? ( dev-python/pygame )"
+	sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )"
 
 DEPEND="${RDEPEND}"
 
-DOCS="CHANGES COPYING README"
+# Fix bug #472774 (https://bugs.gentoo.org/show_bug.cgi?id=472774)
+PATCHES=(
+	"${FILESDIR}/${P}-PIL_modules_imports_fix.patch"
+)
 
-pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
-}
+DOCS=( CHANGES COPYING README )
 
 src_prepare() {
 	# Remove unneeded icon resources update needing running X
@@ -43,13 +42,12 @@
         -e '/^Version.*/d' \
         data/photofilmstrip.desktop
 
-	python_clean_py-compile_files
-	distutils_src_prepare
+	distutils-r1_src_prepare
 }
 
 src_install() {
 	# Do not compress the apps help files
 	docompress -x  /usr/share/doc/${PN}
 
-	distutils_src_install
+	distutils-r1_src_install
 }