bash-completion-2.1-r1.ebuild

bash-completion-2.1-r1.ebuild (text/plain), 1.41 KB, created by Alexander Tsoy on 2013-06-11 04:04:04 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

DESCRIPTION="Programmable Completion for bash"
HOMEPAGE="http://bash-completion.alioth.debian.org/"
SRC_URI="http://bash-completion.alioth.debian.org/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris"
IUSE=""

RDEPEND="
	|| ( >=app-shells/bash-4.1 app-shells/zsh )
	sys-apps/miscfiles
"

PDEPEND="app-shells/gentoo-bashcomp"

src_install() {
	emake install DESTDIR="${D}"
	dodoc AUTHORS CHANGES README

	pushd "${D}"/usr/share/bash-completion/completions

	# Part of >=sys-apps/util-linux-2.23 wrt #468544
	local file
	for file in cal dmesg eject hexdump hwclock ionice look renice rtcwake; do
		rm -f ${file}
	done

	# app-editors/vim-core:
	rm -f xxd

	# Part of >=net-misc/networkmanager-0.9.8.2 wrt #472844
	rm -f nmcli

	# Remove dead symlinks
	find -L . -type l -delete
}

pkg_postinst() {
	if has_version 'app-shells/zsh' ; then
		elog "If you are interested in using the provided bash completion functions with"
		elog "zsh, valuable tips on the effective use of bashcompinit are available:"
		elog "  http://www.zsh.org/mla/workers/2003/msg00046.html"
		elog
	fi
}