icmptx-0.2.ebuild

icmptx-0.2.ebuild (text/plain), 971 bytes, created by Bertrand Jacquin on 2013-06-09 00:56:15 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
inherit git-2 linux-info

DESCRIPTION="IP over ICMP tunnel"
EGIT_REPO_URI="git://github.com/jakkarth/${PN}.git"
EGIT_COMMIT="${PV}"
HOMEPAGE="https://github.com/jakkarth/icmptx"
RDEPEND="virtual/libc"
DEPEND="virtual/os-headers
		${RDEPEND}"
KEYWORDS="~amd64 ~x86 ~ppc"

IUSE="client server"
REQUIRED_USE="|| ( client server )"

LICENSE="GPL-3"
SLOT="0"
RESTRICT="mirror"

CONFIG_CHECK="~TUN"

src_prepare () {
	epatch "${FILESDIR}/${P}-BJA-Makefile.diff"
}

src_compile () {
	emake \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}"
}

src_install() {
	dosbin icmptx
	dodoc README

	if use client ; then
		newinitd "${FILESDIR}"/icmptxcd.init icmptxcd
		newconfd "${FILESDIR}"/icmptxcd.conf icmptxcd
	fi
	if use server ; then
		newinitd "${FILESDIR}"/icmptxd.init icmptxd
		newconfd "${FILESDIR}"/icmptxd.conf icmptxd
	fi
}