jpdftweak-1.1.ebuild

file_331981.txt (text/plain), 923 bytes, created by Tom Wijsman (TomWij) (RETIRED) on 2013-06-08 13:45:40 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"

inherit java-pkg-2 java-ant-2

DESCRIPTION="Swiss Army Knife for PDF files"
HOMEPAGE="http://jpdftweak.sourceforge.net"
SRC_URI="mirror://sourceforge/jpdftweak/${PN}-src-${PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

COMMON_DEPEND="dev-java/itext:5
	dev-java/jgoodies-forms:0"

RDEPEND=">=virtual/jre-1.5
	${COMMON_DEPEND}"

DEPEND=">=virtual/jdk-1.5
	app-arch/unzip
	${COMMON_DEPEND}"

S="${WORKDIR}"

java_prepare() {
	cd lib || die "Failed to enter lib directory."
	java-pkg_jar-from jgoodies-forms forms.jar
	java-pkg_jar-from itext-5 itext.jar
}

EANT_GENTOO_CLASSPATH="itext-5,jgoodies-forms"

src_install() {
	java-pkg_dojar "${PN}.jar"

	java-pkg_dolauncher ${PN} --main jpdftweak.Main

	dodoc "README.txt"
	dohtml manual/*
}