bugle-0.0.20130121.ebuild

bugle-0.0.20130121.ebuild (text/plain), 1.42 KB, created by Richard Grenville on 2013-05-06 04:18:47 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit multilib scons-utils toolchain-funcs eutils

DESCRIPTION="A tool for OpenGL debugging"
HOMEPAGE="http://www.opengl.org/sdk/tools/BuGLe/"
SRC_URI="mirror://sourceforge/bugle/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg gtk"

COMMON_DEPEND="ffmpeg? ( virtual/ffmpeg )
	gtk? ( x11-libs/gtk+:2 x11-libs/gtkglext )
	virtual/opengl
	media-libs/glew
	media-libs/freeglut"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"
RDEPEND="${COMMON_DEPEND}"

pkg_setup() {
	prefix="/usr"
	# We use config=debug to prevent bugle from automatically add '-s' to
	# linker flags ( src/SConscript, apply_compiler() )
	sconsopts=(
		CC="$(tc-getCC)"
		CFLAGS="${CFLAGS}"
		CXXFLAGS="${CXXFLAGS}"
		LINKFLAGS="${LDFLAGS}"
		config=debug
		prefix="${prefix}"
		docdir="${prefix}/share/doc/${P}"
		libdir="${prefix}/$(get_libdir)"
		)
	! use gtk && sconsopts+=( "without_gtk=yes" "without_gtkglext=yes" )
	! use ffmpeg && sconsopts+=( "without_lavc=yes" )
}

src_prepare() {
	# Fix Sandbox violation
	sed -i "s/install_env.AddPostAction(targets, SCons.Action.Action('-ldconfig', '"'$LDCONFIGCOMSTR'"'))/True/" "${S}/site_scons/site_tools/buglewrappers.py" || die
}

src_compile() {
	escons "${sconsopts[@]}"
}

src_install() {
	escons "${sconsopts[@]}" install --install-sandbox="${ED}"
	dodoc -r "${S}/doc/examples"
}