ebuild for FVWM-Crystal-3.1.12

fvwm-crystal-3.1.12.ebuild (text/plain), 1.70 KB, created by Dominique Michel on 2013-05-05 18:54:41 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"

PYTHON_COMPAT=( python2_7 )
inherit eutils python-r1

DESCRIPTION="Configurable and full featured FVWM theme, with lots of transparency and freedesktop compatible menu"
HOMEPAGE="http://fvwm-crystal.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""

RDEPEND="${PYTHON_DEPS}
	>=x11-wm/fvwm-2.6.5[png]
	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
	|| ( >=x11-misc/stalonetray-0.6.2-r2 x11-misc/trayer )
	|| ( x11-misc/hsetroot media-gfx/feh )
	sys-apps/sed
	sys-devel/bc
	virtual/awk
	x11-apps/xwd"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-build.patch
}

src_install() {
	emake \
		DESTDIR="${D}" \
		addondir="/usr/share/doc/${PF}/addons" \
		docdir="/usr/share/doc/${PF}" \
		prefix="/usr" \
		install
}

pkg_postinst() {
	einfo
	einfo "After installation, execute following commands:"
	einfo " $ cp -r /usr/share/doc/${PF}/addons/Xresources ~/.Xresources"
	einfo " $ cp -r /usr/share/doc/${PF}/addons/Xsession ~/.xinitrc"
	einfo
	einfo "Many applications can extend functionality of fvwm-crystal."
	einfo "They are listed in /usr/share/doc/${PF}/INSTALL.gz."
	einfo
	einfo "Some icons fixes was committed recently."
	einfo "To archive the same fixes on your private icon files,"
	einfo "please read /usr/share/doc/${PF}/INSTALL.gz."
	einfo "This will fix the libpng warnings at stderr."
	einfo
	einfo "The color themes was updated to Fvwm InfoStore."
	einfo "To know how to update your custom color themes, please read"
	einfo "	/usr/share/doc/${PF}/addons/convert_colorsets.gz"
	einfo ""
}