# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils linux-info toolchain-funcs user

DESCRIPTION="Tvheadend is a TV streaming server for Linux"
HOMEPAGE="https://tvheadend.org/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi curl dvb ffmpeg inotify xmltv zlib"

DEPEND="dev-libs/openssl
	avahi? ( net-dns/avahi )
	curl? ( net-misc/curl )
	zlib? ( sys-libs/zlib )
	ffmpeg? ( virtual/ffmpeg )
	virtual/linuxtv-dvb-headers
	virtual/pkgconfig"
RDEPEND="${DEPEND}
	dvb? ( media-tv/linuxtv-dvb-apps )
	xmltv? ( media-tv/xmltv )"

DOCS=( README )

pkg_setup() {
	if use inotify ; then
		if ! linux_config_exists || ! linux_chkconfig_present INOTIFY_USER ; then
			ewarn "Please enable Inotify support in your kernel:"
			ewarn "  File systems --->"
			ewarn "    [*] Inotify support for userspace"
		fi
	fi

	enewuser tvheadend -1 -1 /dev/null video
}

src_prepare() {
	# set the version number
	echo "const char *tvheadend_version = \"${PV}\";" \
		> src/version.c || die "setting version failed!"

	# remove '-Werror' wrt bug #438424
	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
}

src_configure() {
	econf --prefix="${EPREFIX}"/usr \
		--datadir="${EPREFIX}"/usr/share \
		--mandir="${EPREFIX}"/usr/share/man/man1 \
		$(use_enable avahi) \
		$(use_enable curl imagecache) \
		--disable-dvbscan \
		$(use_enable ffmpeg libav) \
		$(use_enable inotify) \
		$(use_enable zlib)
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	default

	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
	newconfd "${FILESDIR}/tvheadend.confd" tvheadend

	dodir /etc/tvheadend
	fperms 0700 /etc/tvheadend
	fowners tvheadend:video /etc/tvheadend
}

pkg_postinst() {
	elog "The Tvheadend web interface can be reached at:"
	elog "http://localhost:9981/"
	elog
	elog "Make sure that you change the default username"
	elog "and password via the Configuration / Access control"
	elog "tab in the web interface."
}