arno-iptables-firewall-2.0.1d-r1.ebuild

arno-iptables-firewall-2.0.1d-r1.ebuild (text/plain), 2.28 KB, created by Ferenc Erki on 2013-04-08 15:01:47 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

DESCRIPTION="Arno's iptables firewall script"
HOMEPAGE="http://rocky.eld.leidenuniv.nl"
SRC_URI="http://rocky.eld.leidenuniv.nl/${PN}/${PN}_${PV}.tar.gz"

S=${WORKDIR}/${PN}_${PV}

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+plugins"

# sys-apps/coreutils dependency wrt
# https://bugs.gentoo.org/show_bug.cgi?id=448716

RDEPEND="net-firewall/iptables
	|| ( <sys-apps/coreutils-8.20 >sys-apps/coreutils-8.20-r1 )
	sys-apps/iproute2
	plugins? ( net-dns/bind-tools )"
DEPEND=""

src_prepare() {
	sed -i -e 's:/usr/local/share/:/usr/share/:' \
		etc/arno-iptables-firewall/firewall.conf || die "Sed failed!"
}

src_install() {

	insinto /etc/arno-iptables-firewall
	doins etc/arno-iptables-firewall/firewall.conf
	doins etc/arno-iptables-firewall/custom-rules

	newinitd "${FILESDIR}"/arno-iptables-firewall.rc arno-iptables-firewall

	dobin bin/arno-fwfilter
	dosbin bin/arno-iptables-firewall

	insinto /usr/share/arno-iptables-firewall/
	doins share/arno-iptables-firewall/environment

	dodoc CHANGELOG README

	if use plugins
	then
		insinto /etc/arno-iptables-firewall/plugins
		doins etc/arno-iptables-firewall/plugins/*

		insinto /usr/share/arno-iptables-firewall/plugins
		doins share/arno-iptables-firewall/plugins/*.plugin

		exeinto /usr/share/arno-iptables-firewall/plugins
		doexe share/arno-iptables-firewall/plugins/dyndns-host-open-helper
		doexe share/arno-iptables-firewall/plugins/traffic-accounting-helper
		doexe share/arno-iptables-firewall/plugins/traffic-accounting-log-rotate
		doexe share/arno-iptables-firewall/plugins/traffic-accounting-show

		docinto plugins
		dodoc share/arno-iptables-firewall/plugins/*.CHANGELOG
	fi

	doman share/man/man1/arno-fwfilter.1 \
		share/man/man8/arno-iptables-firewall.8

}

pkg_postinst () {
	ewarn "Make sure to not use multiple firewall scripts simultaneously"
	ewarn "unless you know what you are doing!"
	elog "You will need to configure /etc/${PN}/firewall.conf"
	elog "before using this package. To start the script, run:"
	elog "  /etc/init.d/${PN} start"
	echo
	elog "If you want to start this script at boot, run:"
	elog "  rc-update add ${PN} default"
	echo
	ewarn "When you stop this script, all firewall rules are flushed!"
}