# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils toolchain-funcs user

MY_PN="3.2patch2"

DESCRIPTION="Tvheadend is a TV streaming server for Linux"
HOMEPAGE="https://tvheadend.org/"
SRC_URI="https://github.com/${PN}/${PN}/archive/${MY_PN}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi dvb xmltv zlib"

DEPEND="dev-libs/openssl
	avahi? ( net-dns/avahi )
	zlib? ( sys-libs/zlib )
	virtual/linuxtv-dvb-headers
	virtual/pkgconfig"
RDEPEND="${DEPEND}
	dvb? ( media-tv/linuxtv-dvb-apps )
	xmltv? ( media-tv/xmltv )"

S="${WORKDIR}/${PN}-${MY_PN}"

DOCS=( README )

pkg_setup() {
	enewuser tvheadend -1 -1 /dev/null video
}

src_prepare() {
	# set the correct version number
	sed -e "s:(3.1.694):(${PV}):" -i debian/changelog || die 'sed failed!'

	# remove '-Werror' wrt bug #438424
	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
}

src_configure() {
	econf --prefix="${EPREFIX}"/usr \
		--datadir="${EPREFIX}"/usr/share/ \
		--mandir="${EPREFIX}"/usr/share/man/man1 \
		--release \
		$(use_enable avahi) \
		--disable-dvbscan \
		$(use_enable zlib)
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	default

	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
	newconfd "${FILESDIR}/tvheadend.confd" tvheadend

	dodir /etc/tvheadend
	fperms 0700 /etc/tvheadend
	fowners tvheadend:video /etc/tvheadend
}

pkg_postinst() {
	elog "The Tvheadend web interface can be reached at:"
	elog "http://localhost:9981/"
	elog
	elog "Make sure that you change the default username"
	elog "and password via the Configuration / Access control"
	elog "tab in the web interface."
}