# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit multilib mozextension

GITHUB_USER="infinity0"
GITHUB_PROJECT="${PN}"
GITHUB_HASH="67631ca"

MY_PV="${PV/_p/-UP}"
MY_P="${PN}-${MY_PV}"

MOZILLA_FIVE_HOME="/usr/$(get_libdir)/firefox"

DESCRIPTION="A firefox extension that enables Gnome Keyring integration"
HOMEPAGE="https://github.com/infinity0/mozilla-gnome-keyring"

if [[ ${PV} == "9999" ]] ; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/${GITHUB_USER}/${GITHUB_PROJECT}.git"
else
	SRC_URI="https://github.com/${GITHUB_USER}/${GITHUB_PROJECT}/tarball/${PV} -> ${MY_P}.tar.gz"
	S="${WORKDIR}/${GITHUB_USER}-${GITHUB_PROJECT}-${GITHUB_HASH}"
	KEYWORDS="~x86 ~amd64"
fi

LICENSE="MPL-1.1 GPL-2 LGPL-2.1"
SLOT="0"
IUSE=""

RDEPEND="www-client/firefox[-minimal]
gnome-base/gnome-keyring"
#some of C++11 syntax is used
DEPEND="${RDEPEND}
sys-devel/gcc:4.6"

src_compile() {
	#pkg-config file for Firefox is missing, so we are forced to use hardcodes
	emake VERSION="${PV}" \
		XUL_CFLAGS="-I/usr/include/firefox -I/usr/include/nspr" \
		XUL_LDFLAGS="-L${MOZILLA_FIVE_HOME} -L${MOZILLA_FIVE_HOME}/sdk/lib \
		-lxpcomglue_s -lxul -lxpcom -lmozalloc -lmozsqlite3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl" \
		XPCOM_ABI_FLAGS="-Wl,-rpath=${MOZILLA_FIVE_HOME}"
}

src_install() {
	xpi_install "${S}/xpi"
}