fdutils-5.5-r3.ebuild

fdutils-5.5-r3.ebuild (text/plain), 1.16 KB, created by Michael Mair-Keimberger (mm1ke) on 2013-03-20 17:21:02 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/fdutils/fdutils-5.5-r2.ebuild,v 1.1 2010/09/09 18:24:17 flameeyes Exp $

EAPI="5"

inherit eutils

DESCRIPTION="utilities for configuring and debugging the Linux floppy driver"
HOMEPAGE="http://fdutils.linux.lu/"
SRC_URI="http://fdutils.linux.lu/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86 ~amd64"
IUSE="doc"

RDEPEND=">=sys-fs/mtools-3"

DEPEND="${RDEPEND}
	doc? ( virtual/texi2dvi )"

src_prepare() {
	# the man 4 fd manpage is better in the man-pages package, so stop it
	# from installing
	epatch "${FILESDIR}/${PN}-no-fd.4-manpage.diff"
	epatch "${FILESDIR}/${P}-destdirfix.patch"
	epatch "${FILESDIR}/${P}-fdmount-compilation_linux_2.6.patch"
	sed -i \
		-e '/\$(INSTALL) -c/s/ -s / /' \
		-e 's/${LDFLAFS}/${LDFLAGS}/' \
		src/Makefile.in || die
}

src_configure() {
	econf --enable-fdmount-floppy-only
}

src_compile() {
	# parallel make unsafe (bug#315577)
	emake -j1 $(use doc || echo compile)
}

src_install() {
	dodoc Changelog
	use doc && dodir /usr/share/info/
	dodir /etc
	emake -j1 DESTDIR="${D}" install
}