asdf-2.32.ebuild

asdf-2.32.ebuild (text/plain), 1.34 KB, created by Chema Alonso Josa (RETIRED) on 2013-03-18 19:44:31 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit common-lisp-3

DESCRIPTION="ASDF is Another System Definition Facility for Common Lisp"
HOMEPAGE="http://common-lisp.net/project/asdf/"
SRC_URI="http://common-lisp.net/project/${PN}/archives/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

DEPEND="!dev-lisp/asdf-binary-locations
	doc? ( sys-apps/texinfo )
	test? ( >=dev-lisp/sbcl-1.1.5 )"

S="${WORKDIR}/${PN}"

install_docs() {
	cd doc || die
	dodoc -r asdf index.html asdf.html style.css lisp-logo120x80.png cclan.png asdf.pdf
}

install_package() {
	local name="${1}"
	local dir="${2}"

	[[ -z ${dir} ]] && dir=${name}
	CLPACKAGE="${name}"
	cd "${S}/${dir}" || die
	common-lisp-install-sources *.lisp
	common-lisp-install-asdf ${name}.asd
	insinto "${CLSOURCEROOT}/${name}"
	doins "${S}"/version.lisp-expr
	cd "${S}" || die
}

src_unpack() {
	mkdir "${S}" && cd "${S}" || die
	unpack ${A}
}

src_prepare() {
	sed -i test/run-tests.sh -e '392amkdir -p build/results' || die
}

src_compile() {
	use doc && emake doc
}

src_test () {
	emake test
}

src_install() {
	install_package uiop
	install_package asdf .
	common-lisp-install-sources build/asdf.lisp
	dosym build/asdf.lisp "${CLSOURCEROOT}"/asdf/asdf.lisp
	dodoc README TODO
	use doc && install_docs
}