liferea-1.10_rc1.ebuild

liferea-1.10_rc1.ebuild (text/plain), 1.72 KB, created by Ștefan Talpalaru on 2013-03-17 12:31:31 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.9.6_p20121021.ebuild,v 1.1 2012/10/21 18:27:56 vostorga Exp $

EAPI=4

GCONF_DEBUG=no

inherit autotools eutils gnome2 pax-utils

MY_P=${P/_rc/-RC}
S=${WORKDIR}/${MY_P}

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ayatana libnotify"

RDEPEND="x11-libs/gtk+:3
	>=dev-libs/glib-2.26.0:2
	>=x11-libs/pango-1.4.0
	>=gnome-base/gconf-1.1.9:2
	>=dev-libs/libxml2-2.6.27:2
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.7.0:3
	>=net-libs/libsoup-2.28.2:2.4
	dev-libs/libunique:3
	>=net-libs/webkit-gtk-1.6.1:3
	dev-libs/json-glib
	ayatana? ( dev-libs/libindicate )
	libnotify? ( >=x11-libs/libnotify-0.3.2 )
	>=dev-libs/libpeas-1.0.0[gtk]
	gnome-base/gsettings-desktop-schemas"
DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig"

DOCS="AUTHORS ChangeLog README"

S=${WORKDIR}/${MY_P}

pkg_setup() {
		#--enable-sm
		#--disable-schemas-install
	G2CONF="${G2CONF}
		--disable-schemas-compile
		$(use_enable ayatana libindicate)
		$(use_enable libnotify)"
}

src_prepare() {
	eautoreconf
	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	# bug #338213
	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
	# MPROTECT policy violation. Will sit here until webkit will
	# get optional JIT.
	pax-mark m "${D}"/usr/bin/liferea

	einfo "If you want to enhance the functionality of this package"
	einfo "You should consider installing:"
	einfo "    dev-libs/dbus-glib"
	einfo "    net-misc/networkmanager"
}