dspam-web-3.10.2.ebuild

dspam-web-3.10.2.ebuild (text/plain), 2.49 KB, created by INODE64 Sistemas on 2013-02-28 15:17:45 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/dspam-web/dspam-web-3.10.1.ebuild,v 1.4 2012/02/05 12:14:39 armin76 Exp $

EAPI="4"

inherit webapp user

DESCRIPTION="Web based administration and user controls for dspam"
HOMEPAGE="http://dspam.nuclearelephant.com/"
SRC_URI="http://dspam.nuclearelephant.com/sources/dspam-${PV}.tar.gz"

LICENSE="AGPL-3"
KEYWORDS="amd64 ~ppc x86"
IUSE=""

RDEPEND=">=mail-filter/dspam-${PV}[-user-homedirs]
	dev-perl/GD[png]
	dev-perl/GD-Graph3d
	dev-perl/GDGraph
	dev-perl/GDTextUtil
	www-apache/mod_auth_mysql
	www-servers/apache[suexec]"

need_httpd_cgi

# some FHS-like structure
DSPAM_HOME=/var/spool/dspam
DSPAM_CONF=/etc/dspam

S="${WORKDIR}/dspam-${PV}"

pkg_setup() {
	# create dspam user and group
	dspam_setup_user

	webapp_pkg_setup
}

dspam_setup_user() {
	# DSPAM CGI web gui (www-apps/dspam-web) needs to run as a regular user
	# under suexec in apache, so DSPAM user/group need to be regular users too

	local euid egid
	for euid in {1000..5000} ; do
		[ -z "$(egetent passwd ${euid})" ] && break
	done
	for egid in {1000..5000} ; do
		[ -z "$(egetent group ${egid})" ] && break
	done
	enewgroup dspam ${egid}
	enewuser dspam ${euid} -1 "${DSPAM_HOME}" dspam,mail
}

src_configure() {
	econf \
		--with-dspam-home=${DSPAM_HOME} \
		--sysconfdir=${DSPAM_CONF}
}

src_compile() {
	cd webui
	default
}

src_install() {
	webapp_src_preinst

	cd webui
	insinto "${MY_HTDOCSDIR}"
	insopts -m644
	doins htdocs/*.{css,gif}
	insinto "${MY_CGIBINDIR}/templates"
	doins cgi-bin/templates/{*.html,*.pl}

	for DIR in cs de es-es fr he pt-br ru; do
		insinto "${MY_CGIBINDIR}/templates/${DIR}"
		doins cgi-bin/templates/${DIR}/{*.html,*.pl}
	done

	insinto "${MY_CGIBINDIR}"
	doins cgi-bin/{admins,configure.pl,default.prefs,rgb.txt,*.cgi}

	webapp_configfile "${MY_CGIBINDIR}"/{admins,configure.pl,default.prefs,rgb.txt}

	webapp_hook_script "${FILESDIR}/setperms"
	webapp_postinst_txt en "${FILESDIR}/postinst-en.txt"

	webapp_src_install
}

pkg_postinst() {
	ewarn "If you're using apache dspam-web's config requires the scripts in the cgi-bin"
	ewarn "to be run as dspam:dspam. You will have to put a global SuexecUserGroup"
	ewarn "declaration in the main server config which will force everything in cgi-bin"
	ewarn "to run as dspam:dspam."
	ewarn "You should use a dedicated virtual host for this application or at least"
	ewarn "one that don't have any other cgi scripts."
	ewarn
	webapp_pkg_postinst
}