mali-libs-3_p0.ebuild

mali-libs-3_p0.ebuild (text/plain), 3.81 KB, created by torindel on 2013-02-28 14:02:22 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/mali-libs/mali-libs-r3_p0.ebuild,v 1.0 Exp $

EAPI=5

inherit eutils toolchain-funcs linux-info flag-o-matic git-2

DESCRIPTION="Mali libs"
HOMEPAGE="http://linux-sunxi.org/Mali400"
EGIT_REPO_URI="git://github.com/linux-sunxi/sunxi-mali"
EGIT_HAS_SUBMODULES="1"
SRC_URI=""
LICENSE=""
SLOT="r3p0"
KEYWORDS="~arm"
IUSE="+xorg +fbdev +headers"
RESTRICT="strip"

REQUIRED_USE="|| ( xorg fbdev )"

RDEPEND="
	xorg? ( x11-base/xorg-server media-libs/mesa[gles1,gles2] x11-libs/libdri2 )
	>=app-admin/eselect-opengl-1.2.7
"

DEPEND="${RDEPEND}"

CONFIG_CHECK="~MALI ~MALI400 ~DRM_MALI"
WARNING_MALI="CONFIG_MALI is required for mali-libs to work"
WARNING_DRM_MALI="CONFIG_DRM_MALI is required for xorg support"

QA_PREBUILT="usr/lib/opengl/mali-*/lib/libMali.so"

src_prepare() {
	sed -i -e "s,-mthumb-interwork,,g" lib/ump/Makefile || die
	sed -i -e "s@LDFLAGS +=@LDFLAGS += -Wl,-soname,libUMP.so.3@" lib/ump/Makefile || die
}

src_compile_ver() {
	einfo Compiling mali-libs:${SLOT} for ${1}
	is-flagq "-mfloat-abi=hard" && local FLOAT=armhf || local FLOAT=armel
	local GL_LIB=${1}
	local MALI_ROOT="lib/mali/${SLOT}/${FLOAT}/${GL_LIB}"

	if [ -f config.mk ]; then
		emake -C include clean || die
		emake -C lib clean || die
		rm -f config.mk || die
	fi

	emake config ABI=${FLOAT} VERSION=${SLOT} EGL_TYPE=${GL_LIB} || die
	emake -C include || die
	emake -C lib || die
	gcc -shared -Wl,-soname,libEGL.so.1 -o ${MALI_ROOT}/libEGL.so.1 -L${MALI_ROOT}/ -lMali || die
	gcc -shared -Wl,-soname,libGLESv1_CM.so.1 -o ${MALI_ROOT}/libGLESv1_CM.so.1 -L${MALI_ROOT}/ -lMali || die
	gcc -shared -Wl,-soname,libGLESv2.so.2 -o ${MALI_ROOT}/libGLESv2.so.2 -L${MALI_ROOT}/ -lMali || die
	cp lib/ump/libUMP.so.* ${MALI_ROOT} || die
}

src_compile() {
	use xorg && src_compile_ver x11
	use fbdev && src_compile_ver framebuffer
}

#src_test() { :; } # no tests present

src_install_ver() {
	is-flagq "-mfloat-abi=hard" && local FLOAT=armhf || local FLOAT=armel
	local GL_LIB=${1}
	local MALI_ROOT="lib/mali/${SLOT}/${FLOAT}/${GL_LIB}"
	[ ${GL_LIB} == x11 ] && local INSTALL_ROOT=/usr/$(get_libdir)/opengl/mali-${SLOT}-xorg || local INSTALL_ROOT=/usr/$(get_libdir)/opengl/mali-${SLOT}-fb

	into ${INSTALL_ROOT}
	dolib.so ${MALI_ROOT}/libMali.so
	dolib.so ${MALI_ROOT}/libEGL.so.1
	dosym libEGL.so.1 ${INSTALL_ROOT}/lib/libEGL.so
	dolib.so ${MALI_ROOT}/libGLESv1_CM.so.1
	dosym libGLESv1_CM.so.1 ${INSTALL_ROOT}/lib/libGLESv1_CM.so
	dolib.so ${MALI_ROOT}/libGLESv2.so.2
	dosym libGLESv2.so.2 ${INSTALL_ROOT}/lib/libGLESv2.so
	dolib.so ${MALI_ROOT}/libUMP.so.*
	dosym libUMP.so.3 ${INSTALL_ROOT}/lib/libUMP.so
	#[ ${GL_LIB} == x11 ] && touch ${INSTALL_ROOT}/lib/.gles-only
	[ ${GL_LIB} == x11 ] && dosym /usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so ${INSTALL_ROOT}/lib/libGL.so
	[ ${GL_LIB} == x11 ] && dosym /usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so.1 ${INSTALL_ROOT}/lib/libGL.so.1

	if use headers; then
		insinto ${INSTALL_ROOT}/include/EGL
		doins include/EGL/*.h
		insinto ${INSTALL_ROOT}/include/GLES
		doins include/GLES/*.h
		insinto ${INSTALL_ROOT}/include/GLES2
		doins include/GLES2/*.h
		insinto ${INSTALL_ROOT}/include/KHR
		doins include/KHR/*.h
	fi
	insinto ${INSTALL_ROOT}/include/ump
	doins include/ump/*.h
}

src_install() {
	use xorg && src_install_ver x11
	use fbdev && src_install_ver framebuffer
	insinto /lib/udev/rules.d
	doins "${FILESDIR}"/99-mali-drivers.rules
}

pkg_postinst() {
	elog "To switch to mali opengl/egl, run \"eselect opengl set mali-${SLOT}-xorg\" or \"eselect opengl set mali-${SLOT}-fb\""
	elog
	use xorg && "${ROOT}"/usr/bin/eselect opengl set --use-old mali-${SLOT}-xorg
}

pkg_prerm() {
	"${ROOT}"/usr/bin/eselect opengl set --use-old xorg-x11
}

pkg_postrm() {
	"${ROOT}"/usr/bin/eselect opengl set --use-old xorg-x11
}