# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit eutils distutils-r1 gnome2-utils

DESCRIPTION="An advanced menu editor that provides modern features in a clean, easy-to-use interface"
HOMEPAGE="http://www.smdavis.us/projects/menulibre/"
SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${PN}_${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="dev-python/python-distutils-extra[${PYTHON_USEDEP}]"
RDEPEND="dev-python/pygobject:3[${PYTHON_USEDEP}]
	gnome-base/librsvg
	x11-libs/gtk+:3[introspection]
	x11-themes/hicolor-icon-theme"

S="${WORKDIR}/${PN}"

pkg_setup() {
	python_export_best
}

src_prepare() {
	# Too many categories, just keep the System category which works in Gnome, KDE, XFCE ...
	sed -i 's/Settings;X-GNOME-Settings-Panel;X-GNOME-PersonalSettings;DesktopSettings;//' menulibre.desktop.in || die 'sed on menulibre.desktop.in failed'

	distutils-r1_src_prepare
}

src_install() {
	distutils-r1_src_install
	newicon -s 32 help/C/figures/icon.png menu-editor.png
	dodoc AUTHORS TODO
}

pkg_postinst() {
	gnome2_icon_cache_update
	has_version gnome-extra/yelp || elog "You need gnome-extra/yelp to view help contents"
}

pkg_postrm() {
	gnome2_icon_cache_update
}