kate-4.10.0-r2.ebuild w/ patch for Python 3 expand plugin

kate-4.10.0-r2.ebuild (text/plain), 1.21 KB, created by Alex Turbov on 2013-02-18 04:23:56 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kate/kate-4.10.0.ebuild,v 1.1 2013/02/07 04:57:37 alexxy Exp $

EAPI=5

KDE_HANDBOOK="optional"
KMNAME="kate"
PYTHON_COMPAT=( python{2_7,3_2} )
inherit python-single-r1 kde4-meta eutils

DESCRIPTION="Kate is an MDI texteditor."
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug python +plasma"

DEPEND="
    dev-libs/libxml2
    dev-libs/libxslt
    python? ( $(add_kdebase_dep pykde4 "${PYTHON_USEDEP}" 4.9.2-r1) )
"
RDEPEND="${DEPEND}
    $(add_kdebase_dep katepart)
"

src_prepare() {
    epatch ${FILESDIR}/0001-fixes-for-runtime-errors-w-Python-3.patch
}

pkg_setup() {
    python-single-r1_pkg_setup
    kde4-meta_pkg_setup
}

src_configure() {
    mycmakeargs=(
        $(cmake-utils_use_build python pate)
        $(cmake-utils_use_with plasma)
    )

    kde4-meta_src_configure
}

pkg_postinst() {
    kde4-meta_pkg_postinst

    if ! has_version kde-base/kaddressbook:${SLOT}; then
        echo
        elog "File templates plugin requires kde-base/kaddressbook:${SLOT}."
        elog "Please install it if you plan to use this plugin."
        echo
    fi
}