Experimental ebuild for sdcc-3.2.0

sdcc-3.2.0.ebuild (text/plain), 2.10 KB, created by Tiger on 2013-02-11 18:48:16 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils flag-o-matic

SRC_URI="mirror://sourceforge/sdcc/${PN}-src-${PV}.tar.bz2"
DESCRIPTION="Small device C compiler (for various microprocessors)"
HOMEPAGE="http://sdcc.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+boehm-gc mcs51 z80 z180 r2k r3ka gbz80 ds390 ds400 pic14 pic16 hc08 s08
avr xa51 ucsim +device-lib packihx +sdcpp +sdcdb sdbinutils"
RESTRICT="strip"

RDEPEND="dev-libs/boost
		 dev-util/gperf
		 sys-libs/ncurses
		 sys-libs/readline
		 dev-embedded/gputils
		 boehm-gc? ( dev-libs/boehm-gc )"

DEPEND="${RDEPEND}"

S=${WORKDIR}/${PN}

src_prepare()
{
	# Fix boost issues for pic{14,16} ports
	cd "${S}"
	epatch "${FILESDIR}/${P}-naddr.hpp.patch"
	epatch "${FILESDIR}/${P}-naddr.cc.patch"
	epatch "${FILESDIR}/${P}-tree_dec.hpp.patch"
	epatch "${FILESDIR}/${P}-ralloc.hpp.patch"
	
	# Fix conflicting variable names between Gentoo and sdcc
	find \
			'(' -name 'Makefile*.in' -o -name 'configure' ')' \
			-exec sed -r -i \
				-e 's:\<(PORTDIR|ARCH)\>:SDCC\1:g' \
				{} + || die
}

src_configure()
{
	econf \
		--prefix="${EPREFIX}"/usr \
		--docdir="${EPREFIX}"/usr/share/doc/${P} \
		$(use_enable mcs51 mcs51-port) \
		$(use_enable z80 z80-port) \
		$(use_enable z180 z180-port) \
		$(use_enable r2k r2k-port) \
		$(use_enable r3ka r3ka-port) \
		$(use_enable gbz80 gbz80-port) \
		$(use_enable ds390 ds390-port) \
		$(use_enable ds400 ds400-port) \
		$(use_enable pic14 pic14-port) \
		$(use_enable pic16 pic16-port) \
		$(use_enable hc08 hc08-port) \
		$(use_enable s08 s08-port) \
		$(use_enable avr avr-port) \
		$(use_enable xa51 xa51-port) \
		$(use_enable ucsim ucsim) \
		$(use_enable device-lib device-lib) \
		$(use_enable packihx packihx) \
		$(use_enable sdcpp sdcpp) \
		$(use_enable sdcdb sdcdb) \
		$(use_enable sdbinutils sdbinutils) \
		$(use_enable boehm-gc libgc)
}

src_compile()
{
	emake || die "emake failed."
}

src_install()
{
	emake DESTDIR="${D}" install || die
	
	dodoc doc/README.txt
	
	find "${D}" -name .deps -exec rm -rf {} +
}