teamviewer-7.0.9377.ebuild

teamviewer-7.0.9377.ebuild (text/plain), 2.06 KB, created by Julian Ospald on 2013-02-07 22:46:35 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils gnome2-utils

# Major version
MV=${PV/\.*}
MY_PN=${PN}-${SLOT}
DESCRIPTION="All-In-One Solution for Remote Access and Support over the Internet"
HOMEPAGE="http://www.teamviewer.com"
SRC_URI="http://www.teamviewer.com/download/${PN}_linux.tar.gz -> ${P}.tar.gz"

LICENSE="TeamViewer LGPL-2.1 !system-libs? ( MIT )"
SLOT="7"
KEYWORDS="~amd64 ~x86"
IUSE="system-libs"

RESTRICT="mirror"

RDEPEND="app-shells/bash
	x11-misc/xdg-utils
	system-libs? ( 
		amd64? ( app-emulation/emul-linux-x86-xlibs )
		x86? ( x11-libs/libXtst )
	)"

QA_PREBUILT="opt/teamviewer-7/wine/*
	opt/teamviewer-7/bin/lib_compat/*"

S="${WORKDIR}/teamviewer${MV}"

make_winewrapper() {
	cat << EOF > "${T}/${MY_PN}-swine"
#!/bin/sh
exec wine "/opt/${MY_PN}/wine/drive_c/Program Files/TeamViewer/Version${MV}/TeamViewer.exe" "\$@"
EOF
	chmod go+rx "${T}/${MY_PN}-swine"
	exeinto /opt/bin
	doexe "${T}/${MY_PN}-swine"
}

src_install () {
	insinto /opt/${MY_PN}/bin
	find ".tvscript" -type f -maxdepth 1 -execdir doins '{}' \;
	use system-libs || doins -r "${S}/.tvscript/lib_compat"

	insinto /opt/${MY_PN}/wine
	doins -r "${S}"/.wine/*

	dosym /opt/${MY_PN}/bin/${PN} /opt/bin/${MY_PN}

	make_winewrapper

	doicon -s 48 "${S}"/.tvscript/${PN}.png
	dodoc linux_FAQ_{EN,DE}.txt CopyRights_{EN,DE}.txt

	make_desktop_entry ${MY_PN} TeamViewer
	make_desktop_entry ${MY_PN}-swine "TeamViewer (system wine)"

	# fix permissions
	fperms 755 /opt/${MY_PN}/bin/{${PN},wrapper,killteamviewer}
	fperms 755 /opt/${MY_PN}/wine/bin/*
	fperms 755 "/opt/${MY_PN}/wine/drive_c/Program Files/TeamViewer/Version${MV}"/TeamViewer{,_Desktop}.exe
	find "${D}"/opt/${MY_PN} -type f -name "*.so*" -execdir chmod 755 '{}' \;
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update

	elog "Optionally you can run ${PN} with system wine version via"
	elog "  ${MY_PN}-swine"
	elog "Do not report bugs if you use system wine, it is not supported"
}

pkg_postrm() {
	gnome2_icon_cache_update
}