Complete -r1 ebuild

dot2tex-2.8.7-r1.ebuild (text/plain), 1001 bytes, created by Michał Górny on 2013-02-03 19:08:35 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-tex/dot2tex/dot2tex-2.8.7.ebuild,v 1.20 2012/12/31 13:05:31 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )

inherit distutils-r1

DESCRIPTION="A Graphviz to LaTeX converter"
HOMEPAGE="http://www.fauskes.net/code/dot2tex/"
SRC_URI="http://dot2tex.googlecode.com/files/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
IUSE="doc examples"

DEPEND=""
RDEPEND="virtual/pyparsing[${PYTHON_USEDEP}]
	media-gfx/pydot[${PYTHON_USEDEP}]
	media-gfx/graphviz"

python_install_all() {
	distutils-r1_python_install_all

	if use doc; then
		dohtml -r doc/*
		dodoc doc/usage.{txt,pdf}
	fi
	if use examples; then
		docinto examples
		dodoc examples/.
		docompress -x /usr/share/doc/${PF}/examples
	fi
}