games-emulation/gelide/gelide-9999.ebuild

gelide-9999.ebuild (text/plain), 1.25 KB, created by Jared B. on 2013-01-26 23:01:16 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit games git-2

DESCRIPTION="A flexible frontend for video game emulators"
HOMEPAGE="http://gelide.sourceforge.net/"
SRC_URI=""

EGIT_REPO_URI="git://${PN}.git.sourceforge.net/gitroot/${PN}/${PN}"
EGIT_BOOTSTRAP="autogen.sh"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE="debug nls scrollkeeper"

RDEPEND="app-text/gnome-doc-utils
	dev-cpp/gtkmm
	dev-libs/libxml2
	dev-util/intltool
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )
	scrollkeeper? ( app-text/scrollkeeper )"

src_prepare() {
	# Set emulator paths to gentoo default
	sed -e "s;l_emulator\.setPath(\"[/a-z]*/;l_emulator\.setPath(\"${GAMES_BINDIR}/;" \
		-i "${S}/src/core/default_systems.cpp" || die "sed failed"
}

src_configure() {
	egamesconf \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable scrollkeeper) \
		--docdir=/usr/share/doc/${PF} \
		--localedir=/usr/share/locale \
		--disable-dependency-tracking \
		--datadir=/usr/share \
		|| die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc AUTHORS COPYING ChangeLog NEWS README doc/*.txt

	prepgamesdirs
}