# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit games unpacker-nixstaller

MY_PN=${PN^}
MY_BUILD="2012-12-28"
MY_ARCH=${ARCH/amd64/x86_64}

DESCRIPTION="Puzzle/platformer where only what you can see exists"
HOMEPAGE="http://closuregame.com/"
SRC_URI="${MY_PN}-Linux-${PV}-${MY_BUILD}.sh"

RESTRICT="fetch strip"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="-* amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND="virtual/opengl
	media-gfx/nvidia-cg-toolkit
	media-libs/freealut
	media-libs/libsdl
	media-libs/openal
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libxcb"

S="${WORKDIR}"
GAMEDIR="${GAMES_PREFIX_OPT}/${PN}"

QA_PREBUILT="opt/closure/resources/shaders/*.cgelf"

pkg_nofetch() {
	ewarn "Please download '${A}' and copy to:"
	ewarn "${DISTDIR}"
}

src_unpack() {
	nixstaller_unpack \
		instarchive_all \
		instarchive_linux_${MY_ARCH} \
		|| die "unpack failed"
	rm instarchive* subarch
}

src_install() {
	insinto "${GAMEDIR}"
	exeinto "${GAMEDIR}"

	# install data
	doins -r resource* || die "install data"

	# install binary
	doexe ${MY_PN}.bin.${MY_ARCH} || die "install bin"

	# install documentation
	dodoc README.linux

	# install shortcuts
	doicon "${MY_PN}.png"
	make_desktop_entry "${PN}" "${MY_PN}" "${MY_PN}"
	games_make_wrapper "${PN}" "./${MY_PN}.bin.${MY_ARCH}" "${GAMEDIR}"

	prepgamesdirs
}

pkg_postinst() {
	einfo "To play the game, run:"
	einfo "${PN}"
	games_pkg_postinst
}