ck-sources-3.7.2.ebuild

ck-sources-3.7.2.ebuild (text/plain), 3.84 KB, created by Eric F. GARIOUD on 2013-01-15 16:15:52 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"
ETYPE="sources"
KEYWORDS="~amd64 ~x86"
IUSE="accept_early bfsonly experimental urwlocks"
EARLY_VERSION="yes"

HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches/
	http://users.on.net/~ckolivas/kernel/"

#-- We usually K_WANT_GENPATCHES="base extras" but extras are discontinued from 3.7.1 ---

K_WANT_GENPATCHES="base"

#--

K_GENPATCHES_VER="4"
K_SECURITY_UNSUPPORTED="1"
K_DEBLOB_AVAILABLE="1"

inherit kernel-2
detect_version
detect_arch

K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"

DESCRIPTION="Full Linux ${K_BRANCH_ID} kernel sources with Con Kolivas' high performance patchset and Gentoo's genpatches."

#-- If Gentoo-Sources don't follow then extra incremental patches are needed -

XTRA_INCP_MIN=""
XTRA_INCP_MAX=""

#--

CK_VERSION="1"
BFS_VERSION="426"

CK_FILE="patch-${K_BRANCH_ID}-ck${CK_VERSION}.bz2"
BFS_FILE="${K_BRANCH_ID}-sched-bfs-${BFS_VERSION}.patch"
XPR_1_FILE="bfs${BFS_VERSION}-grq_urwlocks.patch"
XPR_2_FILE="urw-locks.patch"

CK_BASE_URL="http://ck.kolivas.org/patches/3.0"
CK_LVER_URL="${CK_BASE_URL}/${K_BRANCH_ID}/${K_BRANCH_ID}-ck${CK_VERSION}"
CK_URI="${CK_LVER_URL}/${CK_FILE}"
BFS_URI="${CK_LVER_URL}/patches/${BFS_FILE}"
XPR_1_URI="${CK_LVER_URL}/patches/${XPR_1_FILE}"
XPR_2_URI="${CK_LVER_URL}/patches/${XPR_2_FILE}"

#-- Build extra incremental patches list --------------------------------------

LX_INCP_URI=""
LX_INCP_LIST=""
if [ -n "${XTRA_INCP_MIN}" ]; then
	LX_INCP_URL="${KERNEL_BASE_URI}/incr"
	for i in `seq ${XTRA_INCP_MIN} ${XTRA_INCP_MAX}`; do
		LX_INCP[i]="patch-${K_BRANCH_ID}.${i}-$(($i+1)).bz2"
		LX_INCP_URI="${LX_INCP_URI} ${LX_INCP_URL}/${LX_INCP[i]}"
		LX_INCP_LIST="${LX_INCP_LIST} ${DISTDIR}/${LX_INCP[i]}"
	done
fi

#-- Local patches needed for the ck-patches to apply smoothly -----------------

PRE_CK_FIX=""
POST_CK_FIX=""

#--

SRC_URI="${KERNEL_URI} ${LX_INCP_URI} ${GENPATCHES_URI} ${ARCH_URI}
	!bfsonly? ( ${CK_URI} )
	bfsonly? ( ${BFS_URI} )
	experimental? (
		urwlocks? ( ${XPR_1_URI} ${XPR_2_URI} ) )"

if ! use bfsonly ; then
	UNIPATCH_LIST="${LX_INCP_LIST} ${PRE_CK_FIX} ${DISTDIR}/${CK_FILE} ${POST_CK_FIX}"
else
	UNIPATCH_LIST="${LX_INCP_LIST} ${PRE_CK_FIX} ${DISTDIR}/${BFS_FILE} ${POST_CK_FIX}"
fi

if use experimental ; then
	if use urwlocks ; then
		UNIPATCH_LIST="${UNIPATCH_LIST} ${DISTDIR}/${XPR_1_FILE} ${DISTDIR}/${XPR_2_FILE}:1"
	fi
fi

UNIPATCH_STRICTORDER="yes"

pkg_pretend() {
	if [ -n "${EARLY_VERSION}" ]; then
		eerror "This is an early version of the linux ${K_BRANCH_ID} branch."
		eerror "The build of several packages / drivers against this version has been reported broken."
		eerror ""
		if ! use accept_early; then
			eerror "Because the accept_early use flag is not set, this version will not be installed."
			eerror "If you do not want this upgrade to be suggested again on future emerge --update world command,"
			eerror "then you can add the following line to your package.mask file:"
			eerror "=${CATEGORY}/${P}"
			eerror ""
			eerror "If you know that the reported problems do not impact on your system or have been solved"
			eerror "and want to install this version, then you can set the accept_early use flag and re-emerge."
			eerror ""
			die
		else
			eerror "Continuing anyway due to USE=\"accept_early\", but you are aware that"
			eerror "this release might break your configuration and that, depending"
			eerror "on the parameters given to emerge, any future emerge --depclean might"
			eerror "remove from your system the ck-sources < ${PVR} distributions."
		fi
	fi
}

src_prepare() {

#-- Comment out ck's EXTRAVERSION in Makefile ---------------------------------

	sed -i -e 's/\(^EXTRAVERSION :=.*$\)/# \1/' "${S}/Makefile"
}

pkg_postinst() {
	kernel-2_pkg_postinst
	elog
	elog "For more info on this patchset, see: http://forums.gentoo.org/viewtopic-t-941030-start-0.html"
	elog
}