modified ebuild

python-mode-6.1.0.ebuild (text/plain), 1.21 KB, created by MATSUI Tetsushi on 2013-01-14 08:33:32 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/python-mode/python-mode-6.1.0.ebuild,v 1.1 2013/01/04 10:50:38 fauli Exp $

EAPI=4

inherit elisp

MY_P="${PN}.el-${PV}"
DESCRIPTION="An Emacs major mode for editing Python source"
HOMEPAGE="https://launchpad.net/python-mode"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${MY_P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"

S="${WORKDIR}/${MY_P}"
SITEFILE="50${PN}-gentoo.el"
DOCS="NEWS README"

src_compile() {
	elisp-compile autopair/*.el || die

	elisp_src_compile
}

src_install() {
	# install subdirs
	ebegin "Installing Elisp files in subdirs for GNU Emacs support"
	( # subshell to avoid pollution of calling environment
		insinto "${SITELISP}/${PN}/autopair"
		doins autopair/*.el autopair/*.elc
	)
	eend $? "elisp-install: doins failed"

	elisp_src_install
}

pkg_postinst() {
	elisp-site-regen
	elog "Note that doctest and pymacs are in their own packages,"
	elog "app-emacs/doctest-mode and app-emacs/pymacs, respectively."
}