tcplay-0.11.ebuild

tcplay-0.11.ebuild (text/plain), 1.46 KB, created by Jan Nárovec on 2013-01-05 19:25:15 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils toolchain-funcs vcs-snapshot

DESCRIPTION="Free and simple TrueCrypt Implementation based on dm-crypt"
HOMEPAGE="https://github.com/bwalex/tc-play"
SRC_URI="https://github.com/bwalex/tc-play/tarball/v0.11 -> ${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

RDEPEND="dev-libs/libgcrypt
	sys-apps/util-linux
	sys-fs/lvm2"
DEPEND="${RDEPEND}"

# without some kernel modules, this isn't going to work
CONFIG_CHECK="~CRYPTO_RMD160 ~CRYPTO_SHA512 ~CRYPTO_WP512 ~CRYPTO_LRW
~CRYPTO_XTS ~CRYPTO_AES ~CRYPTO_SERPENT ~CRYPTO_TWOFISH ~DM_CRYPT ~BLK_DEV_LOOP"
WARNING_CRYPTO_RMD160="CRYPTO_RMD160 required to use RIPEMD-160 encryption"
WARNING_CRYPTO_SHA512="CRYPTO_SHA512 required to use SHA encryption"
WARNING_CRYPTO_AES="CRYPTO_AES required to use AES encryption"
WARNING_CRYPTO_SERPENT="CRYPTO_SERPENT required to use Serpent encryption"
WARNING_CRYPTO_TWOFISH="CRYPTO_TWOFISH required to use Twofish encryption"
WARNING_DM_CRYPT="DM_CRYPT is required for ${PN} to work!"
WARNING_BLK_DEV_LOOP="BLK_DEV_LOOP is required to mount encrypted volumes in
files"


src_prepare() {
	sed -e '/CFLAGS+= -O3/d' \
		-e '/$(CC)/s:$: $(LDFLAGS):' \
		-i Makefile || die
}

src_compile() {
	tc-export CC
	emake SYSTEM=linux PBKDF_BACKEND=gcrypt program lib
}

src_install() {
	dobin ${PN}
	dolib lib${PN}.so
	doman ${PN}.{3,8}
	dodoc README.md
}