[patch] sauerbraten-2013.01.04.ebuild.diff

sauerbraten-2013.01.04.ebuild.diff (text/plain), 4.26 KB, created by Julian Ospald on 2013-01-05 14:44:51 UTC

--- games-fps/sauerbraten/sauerbraten-2010.07.28.ebuild
+++ games-fps/sauerbraten/sauerbraten-2013.01.04.ebuild
@@ -2,28 +2,29 @@
 # Distributed under the terms of the GNU General Public License v2
 # $Header: /var/cvsroot/gentoo-x86/games-fps/sauerbraten/sauerbraten-2010.07.28.ebuild,v 1.5 2012/12/04 15:37:45 ago Exp $
 
-EAPI=2
-inherit eutils flag-o-matic games
+EAPI=5
+inherit eutils flag-o-matic gnome2-utils games
 
-EDITION="justice_edition"
+EDITION="collect_edition"
 DESCRIPTION="Cube 2: Sauerbraten is an open source game engine (Cube 2) with freeware game data (Sauerbraten)"
 HOMEPAGE="http://sauerbraten.org/"
-SRC_URI="mirror://sourceforge/sauerbraten/2010_07_19/sauerbraten_${PV//./_}_${EDITION}_linux.tar.bz2"
+SRC_URI="mirror://sourceforge/sauerbraten/sauerbraten/2013_01_04/sauerbraten_${PV//./_}_${EDITION}_linux.tar.bz2"
 
 LICENSE="ZLIB freedist"
 SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="debug dedicated"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug dedicated server"
 
 DEPEND="
 	sys-libs/zlib
-	net-libs/enet:1.3
+	>=net-libs/enet-1.3.6:1.3
 	!dedicated? (
 		media-libs/libsdl[X,opengl]
 		media-libs/sdl-mixer[vorbis]
 		media-libs/sdl-image[png,jpeg]
 		virtual/opengl
-		virtual/glu )"
+		virtual/glu
+		x11-libs/libX11 )"
 
 S=${WORKDIR}/${PN}
 
@@ -32,26 +33,19 @@
 	rm -rf sauerbraten_unix bin_unix src/{include,lib,vcpp}
 
 	# Patch makefile to use system enet instead of bundled
-	epatch "${FILESDIR}"/${P}-system-enet.patch
+	# respect CXXFLAGS, LDFLAGS
+	epatch "${FILESDIR}"/${P}-{system-enet,QA,master}.patch
 
 	# Fix links so they point to the correct directory
 	sed -i \
 		-e 's:docs/::' \
 		README.html \
 		|| die
-	# Honor CXXFLAGS and LDFLAGS
-	sed -i \
-		-e 's/[[:space:]]*$//' \
-		-e '/^CXXFLAGS=/d' \
-		-e '/-o .*LIBS/s/$/ $(LDFLAGS)/' \
-		src/Makefile \
-		|| die
 }
 
 src_compile() {
-	use debug && append-flags "-D_DEBUG"
-	emake -C src master server $(use dedicated || echo client) \
-		|| die
+	use debug && append-cppflags -D_DEBUG
+	emake -C src master $(usex dedicated "server" "$(usex server "server client" "client")")
 }
 
 src_install() {
@@ -62,27 +56,28 @@
 	if ! use dedicated ; then
 		# Install the game data
 		insinto "${DATADIR}"
-		doins -r data packages || die
+		doins -r data packages
 
 		# Install the client executable
 		exeinto "${LIBEXECDIR}"
-		doexe src/sauer_client || die
+		doexe src/sauer_client
 
 		# Install the client wrapper
 		games_make_wrapper "${PN}-client" "${LIBEXECDIR}/sauer_client -q\$HOME/.${PN} -r" "${DATADIR}"
 
 		# Create menu entry
-		newicon data/cube.png ${PN}.png
+		newicon -s 256 data/cube.png ${PN}.png
 		make_desktop_entry "${PN}-client" "Cube 2: Sauerbraten"
 	fi
 
 	# Install the server config files
 	insinto "${STATEDIR}"
-	doins "server-init.cfg" || die
+	doins "server-init.cfg"
 
 	# Install the server executables
 	exeinto "${LIBEXECDIR}"
-	doexe src/sauer_{server,master} || die
+	doexe src/sauer_master
+	use dedicated || use server && doexe src/sauer_server
 
 	games_make_wrapper "${PN}-server" \
 		"${LIBEXECDIR}/sauer_server -k${DATADIR} -q${STATEDIR}"
@@ -91,31 +86,41 @@
 
 	# Install the server init script
 	keepdir "${GAMES_STATEDIR}/run/${PN}"
-	cp "${FILESDIR}"/${PN}.init "${T}"
+	cp "${FILESDIR}"/${PN}.init "${T}" || die
 	sed -i \
 		-e "s:%SYSCONFDIR%:${STATEDIR}:g" \
 		-e "s:%LIBEXECDIR%:${LIBEXECDIR}:g" \
 		-e "s:%GAMES_STATEDIR%:${GAMES_STATEDIR}:g" \
 		"${T}"/${PN}.init || die
-	newinitd "${T}"/${PN}.init ${PN} || die
-	cp "${FILESDIR}"/${PN}.conf "${T}"
+	newinitd "${T}"/${PN}.init ${PN}
+	cp "${FILESDIR}"/${PN}.conf "${T}" || die
 	sed -i \
 		-e "s:%SYSCONFDIR%:${STATEDIR}:g" \
 		-e "s:%LIBEXECDIR%:${LIBEXECDIR}:g" \
 		-e "s:%GAMES_USER_DED%:${GAMES_USER_DED}:g" \
 		-e "s:%GAMES_GROUP%:${GAMES_GROUP}:g" \
 		"${T}"/${PN}.conf || die
-	newconfd "${T}"/${PN}.conf ${PN} || die
+	newconfd "${T}"/${PN}.conf ${PN}
 
-	dodoc src/*.txt docs/dev/*.txt
-	dohtml -r README.html docs/*
+	nonfatal dodoc src/*.txt docs/dev/*.txt
+	nonfatal dohtml -r README.html docs/*
 
 	prepgamesdirs
 }
 
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
 pkg_postinst() {
 	games_pkg_postinst
+	gnome2_icon_cache_update
 
 	elog "If you plan to use map editor feature copy all map data from ${DATADIR}"
 	elog "to corresponding folder in your HOME/.${PN}"
 }
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}