An example ebuild with sol. A

unittest2-0.5.1-r1.ebuild (text/plain), 1.41 KB, created by Michał Górny on 2013-01-01 12:35:48 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/unittest2/unittest2-0.5.1.ebuild,v 1.18 2011/07/26 16:26:56 neurogeek Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} pypy{1_8,1_9} )
inherit distutils-r1

DESCRIPTION="Python 2.7/3.2 unittest features backported to Python 2.4+"
HOMEPAGE="http://pypi.python.org/pypi/unittest2 http://pypi.python.org/pypi/unittest2py3k http://code.google.com/p/unittest-ext/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
	mirror://pypi/${PN:0:1}/${PN}py3k/${PN}py3k-${PV}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE=""

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
RDEPEND="${DEPEND}"

DOCS=( README.txt )

python_prepare_all() {
	distutils-r1_python_prepare_all

	copysrc() {
		if [[ ${EPYTHON} == python3* ]]; then
			cp -pr "${WORKDIR}/${PN}py3k-${PV}" "${BUILD_DIR}" || die
		else
			cp -pr "${S}" "${BUILD_DIR}" || die
		fi

		# Disable versioning of unit2 script, we do it anyway.
		sed -e "/'%s = unittest2:main_' % SCRIPT2,/d" \
			-i "${BUILD_DIR}/setup.py" || die
	}
	python_foreach_impl copysrc

	# Delay enabling this to avoid running python_copy_sources.
	DISTUTILS_IN_SOURCE_BUILD=1
}

python_test() {
	./unit2 discover || die
}