# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

EGIT_REPO_URI="git://github.com/JuliaLang/julia.git"

inherit git-2 eutils multilib fortran-2 toolchain-funcs

DESCRIPTION="High-performance dynamic language for technical computing"
HOMEPAGE="http://julialang.org/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc emacs lighttpd"

RDEPEND="
	dev-libs/double-conversion
	dev-libs/gmp
	dev-libs/libpcre
	sci-libs/arpack
	sci-libs/cholmod
	sci-libs/fftw
	sci-libs/umfpack
	sci-mathematics/dsfmt
	sci-mathematics/glpk
	>=sys-devel/llvm-3.1
	sys-libs/libunwind
	sys-libs/readline
	virtual/blas
	virtual/lapack
	lighttpd? ( www-servers/lighttpd )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	# Use system packages instead of included ones
	sed -i \
		-e 's|\(USE_SYSTEM_.*\)=.*|\1=1|g' \
		-e "s|-lblas|$($(tc-getPKG_CONFIG)--libs blas)|" \
		-e "s|-llapack|$($(tc-getPKG_CONFIG) --libs lapack)|" \
		Make.inc || die
	# path for suitesparse is debian specific
	# no need for trivial includes, and it breaks prefix
	sed -i \
		-e 's|\(SUITESPARSE_INC =\).* |\1|' \
		-e 's|-I /usr/include/ ||' \
		deps/Makefile || die
}

src_test() {
	emake -C test
}

src_install() {
	default
}