warzone2100-3.1_rc3.ebuild

warzone2100-3.1_rc3.ebuild (text/plain), 2.28 KB, created by Ambroz Bizjak on 2012-12-05 00:29:33 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/warzone2100-2.3.9.ebuild,v 1.7 2012/07/29 21:18:01 hasufell Exp $

EAPI=4
inherit autotools eutils versionator games

MY_PV=$(get_version_component_range -2)
VIDEOS_PV=2.2
VIDEOS_P=${PN}-videos-${VIDEOS_PV}.wz
DESCRIPTION="3D real-time strategy game"
HOMEPAGE="http://wz2100.net/"
SRC_URI="mirror://sourceforge/warzone2100/${P}.tar.xz
	videos? ( mirror://sourceforge/warzone2100/warzone2100/Videos/${VIDEOS_PV}/high-quality-en/sequences.wz -> ${VIDEOS_P} )"

LICENSE="GPL-2 CCPL-Attribution-ShareAlike-3.0 public-domain"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
# upstream requested debug support
IUSE="debug nls videos +qt"

RDEPEND="dev-db/sqlite:3
	>=dev-games/physfs-2[zip]
	media-libs/libogg
	media-libs/libpng
	!qt? ( media-libs/libsdl[opengl,video] )
	media-libs/libtheora
	media-libs/libvorbis
	media-libs/openal
	!qt? ( media-libs/sdl-net )
	media-libs/quesoglc
	media-libs/glew
	virtual/glu
	virtual/opengl
	nls? ( virtual/libintl )
	x11-libs/libXrandr
	dev-libs/fribidi
	media-libs/freetype
	media-libs/fontconfig
	x11-libs/qt-core
	x11-libs/qt-script
	qt? (
		x11-libs/qt-gui
		x11-libs/qt-opengl
	)"
DEPEND="${RDEPEND}
	sys-devel/bison
	app-arch/zip
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"
RDEPEND="${RDEPEND}
	media-fonts/dejavu"

src_prepare() {
	sed -i \
		-e 's/#top_builddir/top_builddir/' \
		po/Makevars || die

	epatch "${FILESDIR}"/${P}-pkgconf.patch

	# http://developer.wz2100.net/ticket/3818
	epatch "${FILESDIR}/warzone2100-3.1_rc3-gl-save-state-crash.patch"

	eautoreconf
}

src_configure() {
	local backend=sdl
	use qt && backend=qt

	egamesconf \
		--disable-motif \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--localedir=/usr/share/locale \
		--with-distributor="Gentoo ${PF}" \
		--with-icondir=/usr/share/pixmaps \
		--with-applicationdir=/usr/share/applications \
		--with-backend=${backend}
		$(use_enable debug debug relaxed) \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die
	rm -f "${D}"/usr/share/doc/${PF}/COPYING*
	if use videos ; then
		insinto "${GAMES_DATADIR}"/${PN}
		newins "${DISTDIR}"/${VIDEOS_P} sequences.wz || die
	fi
	doman doc/warzone2100.6
	prepgamesdirs
}