games-puzzle/brainworkshop-4.8.4.ebuild

brainworkshop-4.8.4.ebuild (text/plain), 1.08 KB, created by Patrick McMunn on 2012-11-30 00:33:19 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils games

DESCRIPTION="Short-term-memory training N-Back game"
HOMEPAGE="http://brainworkshop.sourceforge.net/"
SRC_URI="mirror://sourceforge/brainworkshop/${P}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="+music"

RDEPEND="dev-python/pyopenal
	|| ( >=dev-python/pyglet-1.1.4[openal]
		 >=dev-python/pyglet-1.1.4[alsa] )
	virtual/opengl
	music? ( =media-libs/avbin-bin-7 )"
DEPEND="app-arch/unzip"

src_unpack() {
	unzip -q "${DISTDIR}"/${P}.zip
	mv ${PN} ${P}
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-fix-paths.patch || die "epatch failed"
	edos2unix ${PN}.pyw
}

src_install() {
	newgamesbin ${PN}.pyw ${PN} || die
	insinto "${GAMES_DATADIR}"/"${PN}"
	doins -r res/i18n res/misc res/sounds res/sprites || die "doins failed"
	if use music; then
		doins -r res/music || die "doins music failed"
	fi
	dodoc Readme.txt data/Readme-stats.txt
	newicon res/misc/brain/brain.png ${PN}.png
	make_desktop_entry "${PN}" "Brain Workshop"
	prepgamesdirs
}