# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

MY_PN="${PN}-201105w"
MY_P="${MY_PN}-${PV}"
TGT="/opt/${MY_PN}"

inherit autotools multilib rpm toolchain-funcs

DESCRIPTION="Epson Inkjet Printer Driver (ESC/P) for Linux"
HOMEPAGE="http://avasys.jp/eng/linux_driver/download/lsb/epson-inkjet/escp/"
SRC_URI="http://linux.avasys.jp/drivers/lsb/epson-inkjet/stable/SRPMS/${MY_P}-1lsb3.2.src.rpm"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

DEPEND="net-print/cups"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}-filter-${PV}"
FILTERDIR="${WORKDIR}/${PN}-filter-${PV}"

src_prepare() {
	sed -i -e 's:/opt/lsb/:/usr/:g' configure.ac || die "sed failed"
	rm configure || die "rm configure file failed"
	eautoreconf
}

src_configure() {
	tc-export_build_env
	# if you have runtime problems: recompile with USE="debug" and look into /tmp/epson-inkjet-printer-filter.txt
	econf \
		--prefix="${TGT}" \
		 $(use_enable debug)
}

src_compile() {
	emake -j1
}

src_install() {
	into "${TGT}"

	# install filter-binary
	exeinto "${TGT}"/cups/lib/filter
	doexe "${FILTERDIR}"/src/epson_inkjet_printer_filter

	cd "${WORKDIR}/${MY_P}"
	# install docs
	dodoc AUTHORS README Manual.txt
	# install ppds-files into /usr/share/ppd/Epson
	gzip -9 ppds/*.ppd
	insinto /usr/share/ppd/Epson
	doins ppds/*.ppd.gz

	# install lib's, recources and watermarks
	insinto "${TGT}"/$(get_libdir)
	doins $(get_libdir)/*

	insinto "${TGT}"/watermark
	doins watermark/*

	insinto "${TGT}"/resource
	doins resource/*
}