# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/genoo-x86/sys-kernel/ck-sources/ck-sources-3.5.4.ebuild,v 1.1 eric-f.garioud

EAPI="3"
ETYPE="sources"

DESCRIPTION="Con Kolivas' high performance patchset + Gentoo patchset sources"
HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches/
	http://users.on.net/~ckolivas/kernel/"

KEYWORDS="~amd64 ~x86"

K_WANT_GENPATCHES="base extras"
K_GENPATCHES_VER="5"
K_SECURITY_UNSUPPORTED="1"

inherit kernel-2 versionator
detect_version
detect_arch

BASE_VERSION="$(get_version_component_range 1-2)"
CK_VERSION="1"
BFS_VERSION="424"

CK_FILE="patch-${BASE_VERSION}-ck${CK_VERSION}.bz2"
BFS_FILE="${BASE_VERSION}-sched-bfs-${BFS_VERSION}.patch"
XPR_1_FILE="bfs${BFS_VERSION}-grq_urwlocks.patch"
XPR_2_FILE="urw-locks.patch"

CK_URI="http://ck.kolivas.org/patches/3.0/${BASE_VERSION}/${BASE_VERSION}-ck${CK_VERSION}/${CK_FILE}"
BFS_URI="http://ck.kolivas.org/patches/bfs/3.0/${BASE_VERSION}/${BFS_FILE}"
XPR_1_URI="http://ck.kolivas.org/patches/bfs/3.0/${BASE_VERSION}/${XPR_1_FILE}"
XPR_2_URI="http://ck.kolivas.org/patches/bfs/3.0/${BASE_VERSION}/${XPR_2_FILE}"

UNIPATCH_STRICTORDER="yes"

IUSE="bfsonly experimental urwlocks"

SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI}
	!bfsonly? ( ${CK_URI} )
	bfsonly? ( ${BFS_URI} )
	experimental? (
		urwlocks? ( ${XPR_1_URI} ${XPR_2_URI} ) )"

if ! use bfsonly ; then 
	UNIPATCH_LIST="${DISTDIR}/${CK_FILE}"
else
	UNIPATCH_LIST="${DISTDIR}/${BFS_FILE}"
fi
if use experimental ; then
	if use urwlocks ; then
		UNIPATCH_LIST="${UNIPATCH_LIST} ${DISTDIR}/${XPR_1_FILE} ${DISTDIR}/${XPR_2_FILE}"
	fi
fi
src_unpack() {
	kernel-2_src_unpack

# Working around BUG 436424
	mv "${S}/linux-3.5.2-bfs/include/linux/urwlock.h" "${S}/include/linux/urwlock.h"
# Comment out EXTRAVERSION added by CK patch:
	sed -i -e 's/\(^EXTRAVERSION :=.*$\)/# \1/' "${S}/Makefile"
}

pkg_postinst() {
	kernel-2_pkg_postinst
	einfo "For more info on this patchset, and how to report problems, see:"
	einfo "${HOMEPAGE}"
}