# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/sancho-bin/sancho-bin-0.9.4.58-r1.ebuild,v 1.7 2012/02/05 05:57:07 vapier Exp $

EAPI="4"

inherit eutils unpacker

MY_P=${P/-bin/}
MY_P=${MY_P%.*}-${MY_P##*.}

DESCRIPTION="The premier graphical user interface for P2P cores. (Currently supports MLDonkey!)"
HOMEPAGE="http://sancho.awardspace.com/"
SRC_URI="
	amd64? ( mirror://gentoo/${MY_P}-linux-gtk-x86_64-java.sh )
	x86? ( mirror://gentoo/${MY_P}-linux-gtk-java.sh )
"
## Unfortunately, the file for this is not available anymore.
## (Unless the developer answers my mail.)
#	ppc? ( mirror://gentoo/${MY_P}-linux-gtk-ppc-java.sh )

RESTRICT="strip"

KEYWORDS="~amd64 ~x86" # ~ppc
SLOT="0"
LICENSE="CPL-1.0 LGPL-2.1"
IUSE=""

DEPEND="
	x11-libs/libXxf86vm
	x11-libs/libXext
	x11-libs/libX11
	x11-libs/gtk+:2
	>=virtual/jre-1.5
"

S="${WORKDIR}"

src_unpack() {
	unpack_makeself
}

src_install() {
	dodir /opt/sancho
	dodir /opt/bin

	cp -dpR sancho distrib lib "${D}/opt/sancho"

	exeinto /opt/sancho
	doexe sancho

	exeinto /opt/bin
	newexe "${FILESDIR}/0.9.4.59-sancho.sh" sancho

	insinto /etc/revdep-rebuild
	doins "${FILESDIR}/50-${PN}"

	make_desktop_entry sancho sancho /opt/sancho/distrib/sancho-32.xpm
}

pkg_postinst() {
	elog
	elog "Sancho requires the presence of a p2p core, like"
	elog "net-p2p/mldonkey, in order to operate. This core"
	elog "may be on another machine of your network."
	elog
}