New version -- gap-4.5_p5

gap-4.5_p5.ebuild (text/plain), 2.23 KB, created by Marek on 2012-09-18 12:44:57 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

inherit elisp-common versionator

XTOM_VERSION=1r1p4

PV1=$(get_version_component_range 1-2 )
PV2=$(get_version_component_range 3 )
PV1=$(replace_version_separator 1 'r' ${PV1} )
PV2=${PV1}${PV2}
DATE=2012_07_16-17_17

DESCRIPTION="System for computational discrete algebra"
HOMEPAGE="http://www.gap-system.org/"
SRC_URI="
	ftp://ftp.gap-system.org/pub/gap/gap4/tar.bz2/${PN}${PV2}_${DATE}.tar.bz2
	xtom? ( ftp://ftp.gap-system.org/pub/gap/gap4/tar.bz2/xtom${XTOM_VERSION}.tar.bz2 )"

SLOT="0"
IUSE="emacs gmp readline static-gmp vim-syntax xtom"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

RDEPEND="
	emacs? ( virtual/emacs )
	gmp? ( dev-libs/gmp )
	readline? ( sys-libs/readline )
	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="${RDEPEND}"

S="${WORKDIR}"/${PN}${PV1}

src_configure() {
	myconf+=$(use_with readline)
	if use static-gmp ; then
		econf \
			--with-gmp \
			$myconf
	fi
	if use gmp; then
		econf \
			--with-gmp=system \
			$myconf
	else
		econf \
			--without-gmp \
			$myconf
	fi
}

src_compile() {
	emake CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" compile || die "emake failed"
}

src_test() {
	emake teststandard || die "test failed"
}

src_install() {
	dodoc README description*
	insinto /usr/share/${PN}
	doins -r doc grp lib pkg prim small trans tst sysinfo.gap
	source sysinfo.gap
	exeinto /usr/libexec/${PN}
	doexe bin/${GAParch}/gap
	sed -e "s|@gapdir@|/usr/share/${PN}|" \
		-e "s|@target@-@CC@|/usr/libexec/${PN}|" \
		-e "s|@EXEEXT@||" \
		-e 's|$GAP_DIR/bin/||' \
		gap.shi > gap
	exeinto /usr/bin
	doexe gap

	if use emacs ; then
		elisp-site-file-install etc/emacs/gap-mode.el
		elisp-site-file-install etc/emacs/gap-process.el
		elisp-site-file-install "${FILESDIR}"/64gap-gentoo.el
		dodoc etc/emacs/gap-mode.doc
	fi

	if use vim-syntax ; then
		insinto /usr/share/vim/vimfiles/syntax
		doins etc/gap.vim
		insinto /usr/share/vim/vimfiles/indent
		newins etc/gap_indent.vim gap.vim
		insinto /usr/share/vim/vimfiles/plugin
		newins etc/debug.vim debug_gap.vim
		dodoc etc/README.vim-utils etc/debugvim.txt
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}